GCC中汇编文件的for循环宏/预处理器

Question

我相当肯定我以前在代码中看到过这一点，但我找不到任何关于如何做到这一点的参考资料。我确实希望这是特定于编译器或汇编器的。

我想定义一个（编译时）固定长度的函数指针数组，用作嵌入式设备上的中断向量表。每个处理程序将在跳转到公共处理程序之前推送其中断号。为这些更简单的函数创建宏很简单：

.macro irq number
    .global irq\number
    irq\number:
    pushd $\number
    jmp irq_handler_common
.endm

然后可以像这样手动定义这些：

irq 0
irq 1
irq 2
...

但是，我不希望通过手动定义其中的 256 个来弄乱我的 ASM 文件。因此，我想做的是使用像预处理器/宏这样的 for 循环，它可以让我做这样的事情：

for i in 0 ... 255
    irq i

这可以通过使用宏来完成吗？

Answer 1

使用@MichaelPetch 和@Jester 的建议我已经编译了以下工作解决方案（需要使用altmacro 的GNU 汇编程序或其他支持汇编程序）。不幸的是，我不得不创建两个宏，一个用于实例化中断入口点存根，另一个用于帮助创建这些入口地址的向量。如果我尝试在创建default_handlers 的.rept 中使用.long irq %i，我正在观察Error: invalid operands (*UND* and *ABS* sections) for %。如果有人有更小/更简单的解决方案，请发布！

定义特定于每个处理程序条目的入口点

.macro irq_stubX number
    irq\number:
    pushd $\number
    jmp irq_handler_common
.endm

使用这个宏（和altmacro），创建256个实例

.altmacro

.section .text
.set i,0
.rept 256
    irq_stubX %i
    .set i,i+1
.endr

最后，使用另一个宏，创建一个我们刚刚在上面创建的标签的向量。

.section .data
.macro irq_labelX number
    .long irq\number
.endm

default_handlers:
.set i,0
.rept 256
    irq_labelX %i
    .set i, i+1
.endr

供参考，这样不行，报上面提到的错误：

default_handlers:
.set i,0
.rept 256
    .long irq %i
    .set i, i+1
.endr

---

编辑。根据下面的@RossRidge's 建议，可以使解决方案更小更清晰。

.altmacro

.macro irq_insertX number
    .section .text
    irq_stubX \number

    .section .data
    .long irq\number
.endm

.section .data
default_handlers:
.set i,0
.rept 256
    irq_insertX %i
    .set i, i+1
.endr