从 x86-64 打印浮点数似乎需要保存 %rbp

Question

当我在 Ubuntu 上使用 gcc 4.6.1 编写一个与 C 库链接的简单汇编语言程序，并尝试打印一个整数时，它工作正常：

        .global main
        .text
main:
        mov     $format, %rdi
        mov     $5, %rsi
        mov     $0, %rax
        call    printf
        ret
format:
        .asciz  "%10d\n"

这打印出 5，正如预期的那样。

但是现在如果我做一个小改动，并尝试打印一个浮点值：

        .global main
        .text
main:
        mov     $format, %rdi
        movsd   x, %xmm0
        mov     $1, %rax
        call    printf
        ret
format:
        .asciz  "%10.4f\n"
x:
        .double 15.5

这个程序段错误没有打印任何东西。只是一个可悲的段错误。

但我可以通过推送和弹出%rbp 来解决此问题。

        .global main
        .text
main:
        push    %rbp
        mov     $format, %rdi
        movsd   x, %xmm0
        mov     $1, %rax
        call    printf
        pop     %rbp
        ret
format:
        .asciz  "%10.4f\n"
x:
        .double 15.5

现在它可以工作了，并打印 15.5000。

我的问题是：为什么推送和弹出%rbp 使应用程序工作？根据 ABI，%rbp 是被调用者必须保留的寄存器之一，因此printf 不能搞砸它。事实上，printf 在第一个程序中起作用，当时只有一个整数被传递给printf。那么问题一定出在其他地方？

Answer 1

我怀疑这个问题与%rbp 没有任何关系，而是与堆栈对齐有关。引用 ABI：

ABI 要求堆栈帧在 16 字节边界上对齐。具体来说，结束 参数区域（%rbp+16）必须是 16 的倍数。这个要求意味着帧 size 应填充为 16 字节的倍数。

当您输入main() 时，堆栈对齐。调用printf() 将返回地址压入堆栈，将堆栈指针移动8 个字节。您可以通过将另外 8 个字节压入堆栈来恢复对齐（恰好是 %rbp，但也可以很容易地成为其他东西）。

这是gcc 生成的代码（也是on the Godbolt compiler explorer）：

.LC1:
        .ascii "%10.4f\12\0"
main:
        leaq    .LC1(%rip), %rdi   # format string address
        subq    $8, %rsp           ### align the stack by 16 before a CALL
        movl    $1, %eax           ### 1 FP arg being passed in a register to a variadic function
        movsd   .LC0(%rip), %xmm0  # load the double itself
        call    printf
        xorl    %eax, %eax         # return 0 from main
        addq    $8, %rsp
        ret

如您所见，它通过在开头从 %rsp 中减去 8 并在末尾添加回来来处理对齐要求。

您可以改为对您喜欢的任何寄存器进行虚拟推送/弹出，而不是直接操作%rsp； some compilers do use a dummy push to align the stack 因为 this can actually be cheaper 在现代 CPU 上，并且节省了代码大小。