在 Excel 中插入分页符以拆分数据以打印 .pdf

Question

我正在使用可以包含动态行的 Excel 文件。我将它导出为 .pdf 并且效果很好。问题是所有内容都在 .pdf 文件的一个页面上。

是否可以在我的 .pdf 文件的 VBA 中插入分页符？

编辑：这是我的分页代码。似乎无法正常工作

If count > 30 Then ' count is the number of row. Break at every 15 rows
        Set ws = Range("A1", "K" & count) 'The range of the document
        Dim ii As Integer
        ii = 21 ' first page break
        While count > 0
            If count > 15 Then ' no page break if there is less than 15 rows
             ws.Rows(ii).EntireRow.PageBreak = xlPageBreakManual
            End If               
            ii = ii + 15
            count = count - 15
        Wend
End If

编辑 2： 我没有找到任何方法在 pdf 文件中创建分页符。但是，我仍然解决了我的问题。我只是为 vba 找到一个模块来运行外部进程并等待它们。是ShellAndWait

我将 pdf 文件的每一页都保存为临时文档，并将其路径/名称发送到我创建的 C# 控制台应用程序。我正在使用库 PDFsharp 来处理 pdf 文档，然后将它们合并到 1 个文件中。

希望它可以帮助某人。

Answer 1

您可以像这样设置分页符：

Worksheets("Sheet1").HPageBreaks.Add Before:=Worksheets("Sheet1").Rows(25)
Worksheets("Sheet1").VPageBreaks.Add Before:=Worksheets("Sheet1").Columns("J")

Worksheets("Sheet1").Rows(25).PageBreak = xlPageBreakManual
Worksheets("Sheet1").Columns("J").PageBreak = xlPageBreakManual

仅供参考，我没能让Range.PageBreak 工作

或者对于一个范围，类似这样：

With Range(blabla)
    .Rows(.Rows.Count).EntireRow.PageBreak = xlPageBreakManual
    '.Rows(Int(.Rows.Count/2)).EntireRow.PageBreak = xlPageBreakManual
    .Columns(.Columns.Count).EntireColumn.PageBreak = xlPageBreakManual
End With

---

这是您更正后的代码：

Sub test_Wanceslas()
Dim Ws As Worksheet, _
    Rg As Range, _
    LastRow As Long, _
    Count As Long, _
    ii As Long

ii = 21 ' first page break
Set Ws = ActiveSheet

With Ws
    LastRow = .Range("A" & .Rows.Count).End(xlUp).Row
    Count = LastRow
    Set Rg = .Range("A1", "K" & Count) 'The range of the document

    If LastRow > 30 Then ' count is the number of row. Break at every 15 rows
        .ResetAllPageBreaks
        .PageSetup.PrintArea = Rg.Address

        While Count > 0 And ii < LastRow
            If Count > 15 Then ' no page break if there is less than 15 rows left
                '.Rows(ii).PageBreak = xlPageBreakManual
                .HPageBreaks.Add Before:=.Rows(ii)
            End If
            ii = ii + 15
            Count = Count - 15
        Wend
    End If
End With

End Sub