VBA 和 Excel：选择所选内容下方的行

Question

我知道这个问题可能会被问到很多，但我无法找到或理解我正在寻找的确切答案。

我今天第一次在 excel 中学习 VBA，我正在尝试自动格式化一个值表，并希望它适用于不同的范围大小。

我不知道如何在我的选择中选择最后一行下方的行并设置格式。

到目前为止我的代码是：

Selection.CurrentRegion.Select

Selection.Rows("1:1").Interior.Color = 12155648

With Selection.Rows("1:1").Font

    .ThemeColor = xlThemeColorDark1

    .Bold = True

End With



Selection.CurrentRegion.Select

Selection.Cells(Selection.Rows.Count, Selection.Columns.Count).Select

   

Selection.Interior.Color = 12632256

Selection.Font.Bold = True

Selection.Range("A1").Value = "Total"

我想要发生的事情：

Original

Desired Formatting

Answer 1

把它变成一个实际表格怎么样

Sub Demo()
    With ActiveSheet.ListObjects.Add(xlSrcRange, ActiveCell.CurrentRegion, , xlYes)
        .Name = "MyTable" ' optional
        .ShowTotals = True
    End With
End Sub

之前

之后

Answer 2

不，这不是一个常见的问题，因为大多数程序员在第二天（即您的日程安排中的明天）学习不要“选择”任何东西，而是使用 Range 对象。然后你的代码看起来更像这样：-

Private Sub Snippet()

    Dim Rng     As Range

    With Selection.CurrentRegion
        .Rows(1).Interior.Color = 12155648
        With .Rows(1).Font
            .ThemeColor = xlThemeColorDark1
            .Bold = True
        End With
        Set Rng = ActiveSheet.Cells(.Row + .Rows.Count, .Column).Resize(1, .Columns.Count)
    End With
    
    With Rng
        .Interior.Color = 12632256
        .Font.Bold = True
        .Cells(1).Value = "Total"
    End With
End Sub

Answer 3

您可以使用以下方法，假设您的表格从B4开始：

Sub ty()

Dim lastrow As Long

lastrow = Sheet1.Range("B4").End(xlDown).Row + 1

With Sheet1.Range("B4").Resize(1, 5)
    .Interior.Color = 12155648
    .Font.ThemeColor = xlThemeColorDark1
    .Font.Bold = True
End With

Sheet1.Cells(lastrow, 2).Value = "Total"

With Sheet1.Cells(lastrow, 2).Resize(1, 5)
    .Interior.Color = 12632256
    .Font.Bold = True
End With


End Sub