词法变量在 eval 中“不可用”的警告的原因是什么

Question

当eval 语句在词法变量的范围内时，该变量应该在评估块的词法上下文中。此外，词法变量应该在 subs 的词法上下文中可用。

但这不起作用：

use warnings;

{
    package VLE;

    my $ln10 = 2.302585092994045684017991454684;

    sub reval {
        say eval $_[0] if @_;
    }
}

package VLE;

reval( q($ln10) );

结果：

Variable "$ln10" is not available at (eval 1) line 1.

但是如果我（无用地）在块中的任何地方使用词法变量，它会突然在 eval 中可用：

use warnings;

{
    package VLE;

    my $ln10 = 2.302585092994045684017991454684;

    sub reval {
        say eval $_[0] if @_;
        my (undef) = $ln10;
        return 0
    }
}

package VLE;

reval( q($ln10) );

打印

2.30258509299405

为什么会这样？

编辑：

引用的破坏不是问题，因为这段代码（维护对$ln10的引用）也失败了：

use warnings;

{
    package VLE;

    my $ln10 = 2.302585092994045684017991454684;

    sub reval2 {
        say eval $_[0] if @_;
        my (undef) = $ln10;
        return 0
    }

    sub reval {
        say eval $_[0] if @_;
        return 0
    }
}

package VLE;

reval( q($ln10) ); # still fails
reval2( q($ln10) ); # works

Answer 1

子程序不会关闭（捕获）所有可见的词法变量，而只会关闭那些在子程序体中引用的变量。这是引用计数正常工作的一个非常重要的部分。捕获哪些变量在编译时确定，在执行子程序定义时捕获变量（命名子程序的编译时间，匿名子程序的运行时间）。

这里您的第一个reval 没有捕获$ln10 变量。因此，它在 eval 中不可用。由于 eval 字符串是运行时值，因此在确定应捕获哪些变量时无法将其考虑在内。

更准确地说，$ln10 变量在离开封闭块时被销毁，因为不存在对它的进一步引用。所以这段代码可以工作，因为在执行 eval 时 $ln10 变量仍然存在：

use warnings;
{
    package VLE;
    my $ln10 = 2.302585092994045684017991454684;

    sub reval {
        say eval $_[0] if @_;
    }

    reval(q($ln10));
    # $ln10 variable exists until here
}

第二个eval 确实捕获了变量，因此它的生命周期会延长到执行 eval 的时间点，并且一切都按预期工作。