gnuplot rowstacked histogram：如何计算标准偏差并将其放在条形图上？答案

【问题标题】：gnuplot rowstacked histogram: how to calculate and put standard deviations on top of bars?gnuplot rowstacked histogram：如何计算标准偏差并将其放在条形图上？
【发布时间】：2015-09-11 03:11:32
【问题描述】：

我提出一个新问题是因为How to plot histograms from rows in data file gnuplot 中的更新没有受到太多关注。相关问题：gnuplot histogram: How to put values on top of bars和gnuplot rowstacked histogram: how to put sum above bars

t.dat 文件如下所示：

目标是计算文件 t.dat 中四组数字的标准差，并将它们显示为组成直方图的条形上方的标签。第 1 组：第 1-40 行第 2 组：第 41-80 行第 3 组：第 81-120 行第 4 组：第 121-160 行

到目前为止，我只能手动完成此操作。我已将所需的行范围拆分为单个文件，即。 e. tempos1.dat、tempos4.dat、tempos9.dat 和 tempos16.dat，使用统计数据计算它们的标准偏差并将它们显示为标签。

代码如下：

set term pngcairo
set out 'st-dev.png'
unset key
stats "tempos1.dat" using 1 name "A"
stats "tempos4.dat" using 1 name "B"
stats "tempos9.dat" using 1 name "C"
stats "tempos16.dat" using 1 name "D"
set label "0.6234" at 28,275
set label "0.4666" at 90,90
set label "0.9836" at 149,85
set label "0.2947" at 210,65
set boxwidth 0.9 relative
set style data histogram
set style histogram cluster gap 1
set style fill solid 1.0 border -1
set xrange [0:250]
set xtics ("1" 40, "4" 100, "8" 160, "16" 220)
plot for [i=1:4] 't.dat' using ($0+20+(i-1)*61):1 every ::((i-1)*40)::(i*40-1) with boxes lt i

我阅读了相关帖子，看来，要将 std dev 放在条形之上，我所要做的就是在 using 子句中添加一个列，其中包含存储 std_dev 的变量，但现在它是通过手动拆分的文件计算的。这是所需的输出：

我该怎么做？

【问题讨论】：

你的更新没有受到太多关注，因为更新不是为了问一个基本的新问题；）

标签： gnuplot histogram standard-deviation

【解决方案1】：

您可以使用do for 遍历四个块，使用与plot 命令中相同的using 和every 设置调用stats。然后，在每次迭代中，使用stats 为您提供的许多值设置适当的标签：

STATS_mean_x 作为标签的 x 坐标
STATS_max_y 作为 y 坐标（加上 1 个字符高度的偏移，使用 set label ... offset 0,1 完成）
STATS_stddev_y 作为计算标准差本身：

set term pngcairo
set out 'st-dev.png'
unset key
set boxwidth 0.9 relative
set style fill solid 1.0 border -1
set xlabel "Número de processos"
set ylabel "Tempo de execução (s)"
set xrange [0:250]
set xtics ("1" 40, "4" 100, "8" 160, "16" 220)

do for [i=1:4] {
    stats 't.dat' using ($0+20+(i-1)*61):1 every ::((i-1)*40)::(i*40-1) nooutput
    set label i sprintf('%.4f', STATS_stddev_y) center at STATS_mean_x,STATS_max_y offset 0,1
}

plot for [i=1:4] 't.dat' using ($0+20+(i-1)*61):1 every ::((i-1)*40)::(i*40-1) with boxes lt i

【讨论】：

我测试了您的代码，但收到“期望 [no] 输出或前缀”错误消息。 gnuplot 将错误指向脚本中单词“offset”的第二个“f”字母。
Ups，是的，代码格式被前面的列表搞砸了。我现在修好了。现在工作正常（用 4.6.0、4.6.6 和 5.0 测试）