使用 VBA 从 Visio Shapes 导出数据

Question

我想在 MS Visio 2016 Professional 中建模类似于（超）图的东西，然后将形状的数据导出到 csv 以进一步使用它。

我正在尝试制作一个 VBA 脚本，它遍历工作表上的所有形状，并将形状中的（手动插入的）数据写入一个 csv 文件（将来可能会根据类型的不同 csv 文件形状）。

为了了解 VBA，我尝试从一个脚本开始计算工作表上的所有形状，但我已经失败了。请考虑这是我第一次使用 VBA：

Sub countShapes()
Dim shp As Shape
Dim count As Integer
count = 0
Debug.Print count

For Each shp In ActiveSheet.Shapes
count = count + 1
Debug.Print count
Next

End Sub

这会返回运行时错误 424，找不到对象。

我错过了什么？

作为第二步，我希望脚本检查数据字段“id”中具有相同数字的形状在所有其他数据字段中是否相同，如果不是则显示错误（在导出到csv 文件）。我可以在 visio 中使用 vba 实现这一点吗？

非常感谢您的帮助！

Answer 1

ActiveSheet 是 Excel 属性。我认为您正在寻找 ActivePage，这是 Visio 等价物。因此，要修复上面的代码，您可以使用以下代码：

For Each shp In ActivePage.Shapes
    count = count + 1
    Debug.Print count
Next

但是，如果您只是追求页面的形状计数，那么您可以改为这样写：

Debug.Print ActivePage.Shapes.Count

我能否推荐一些可能也有帮助的链接：

• http://visualsignals.typepad.co.uk/vislog/2007/10/just-for-starte.html
• http://visualsignals.typepad.co.uk/vislog/2007/11/looping-through.html
• vba programming for visio

作为一种替代方法，您可能还对 Visio 的内置报告工具感兴趣：

• Create a report of shape data（支持文档）
• Getting Started with Visio 16 - Build and Apply Reports from Share Data (Video)

关于您问题的第二部分（检查数据字段）我假设您正在谈论阅读形状数据。如果是这种情况，您首先要检查是否存在名为“ID”的行，如果存在，请读取该值。所以这样的事情可能会让你继续前进：

Public Sub TestGetCellValues()
    GetShapesCellValues ActivePage, "Prop.ID"
End Sub

Public Sub GetShapesCellValues(targetPage As Visio.Page, targetCellName As String)
Dim shp As Visio.Shape
If Not targetPage Is Nothing Then
    For Each shp In targetPage.Shapes
        If shp.CellExistsU(targetCellName, 0) = True Then
            Debug.Print shp.NameID & "!" _
                & targetCellName & " = " _
                & shp.CellsU(targetCellName).ResultIU
        End If
    Next shp
End If
End Sub

...可能会输出类似这样的内容（给定相关的形状）：

Sheet.2!Prop.ID = 3