【问题标题】:How to export many variables of a simulation result to csv?如何将模拟结果的多个变量导出到 csv?
【发布时间】:2020-01-01 21:24:00
【问题描述】:

我正在尝试通过 csv 文件将我的结果从 Dymola 导出到 excel。但我有很多结果。如何将它们写入数组??

我尝试创建一个 for 循环,但我不知道如何键入代码。

if (time) <= 0 then
   Modelica.Utilities.Files.removeFile("tube_0.02"+".csv");
   Modelica.Utilities.Streams.print("temps," +
      "delta_fr1,"+
      "delta_fr2,"+
      "delta_fr3,",
    "tube_0.02"+".csv");
 else

 Modelica.Utilities.Streams.print(String(time) +
   "," + String(   my_code_tube1[1].delta_fr)+
   "," + String(   my_code_tube1[2].delta_fr)+
   "," + String(   my_code_tube1[3].delta_fr),
     "tube_0.02"+".csv");

 end if;

不必编写 delta_fr1, delta_fr2... 然后 my_code_tube1[1].delta_fr, my_code_tube1[2].delta_fr.... 我需要创建一个 for 循环,因为我将有将近 1500 个变量要导出。

【问题讨论】:

    标签: arrays for-loop export-to-csv dymola


    【解决方案1】:

    在模拟过程中尝试将结果写入 csv 文件会在 Modelica 中遇到一些问题:

    • 您希望在哪些时间步长上写入结果?无法使用求解器步长。 但是我们可以使用sample()函数定义一个周期性输出

    • 调用 print 非常昂贵。在模拟运行时,您不希望这样做太多次

    • 打印函数总是在每次调用后添加一个换行符。这要求我们一次编写每一行(但由于前面提到的性能限制,无论如何我们应该一次编写尽可能多的文本)。 不幸的是,Dymola 的默认最大字符串大小非常小,限制在 500。 您必须通过设置例如确保当前 Dymola 实例使用适当的大值。 Advanced.MaxStringLength = 50000.

    考虑到这些,我们可以想出如下代码:

    model SO_print_for
      My_code_tube my_code_tube1[1500];
    
    protected 
      String line;
      String f="tube_0.02" + ".csv";
    
      model My_code_tube
        Real delta_fr=1;
      end My_code_tube;
    
    initial algorithm 
      line := "temps";
      for i in 1:size(my_code_tube1,1) loop
        line := line + ", delta_fr" + String(i);
      end for;
      Modelica.Utilities.Files.removeFile(f);
      Modelica.Utilities.Streams.print(line, f);
    
    algorithm 
      when sample(0, 0.1) then
        line := String(time);
        for i in 1:size(my_code_tube1,1) loop
          line := line + ", "+String(my_code_tube1[i].delta_fr);
        end for;
        Modelica.Utilities.Streams.print(line, f);
      end when;
    
    end SO_print_for;
    

    代码有效,但它会减慢您的模拟速度,因为会生成很多时间事件(来自sample() 函数)。

    不要在模拟过程中编写 csv,而应考虑在模拟完成后转换结果文件的以下方法之一:

    • 使用 Dymola 变量浏览器中的导出结果将所有或仅绘制的变量导出到 csv。这必须在每次模拟后手动完成,并且不能脚本化

    • 使用函数DataFiles.convertMATtoCSV。以下两行代码将从.mat结果文件中提取1500个delta_fr变量

        vars = {"my_code_tube1["+String(i)+"].delta_fr" for i in 1:1500}
        DataFiles.convertMATtoCSV("your-model.mat", vars, "out.csv")
    
    • 使用 Matlab、Octave 或 FreeMat 打开 .mat 结果文件并将其转换为 Excel 可以理解的文件格式。 Dymola 提供dymload.m 将 .mat 结果文件导入 Matlab。详见 Dymola 用户手册第 1 卷

    • 使用 python 将结果转换为 csv 文件,例如通过使用包DyMat或SDF-Python,它们都可以用来读取结果文件

    【讨论】:

    • 感谢您的回答。我在打印函数中添加了时间变量。我会试试你的方法,谢谢。
    • 实际上有两种方法可以编写从 Dymola 导出 CSV 的脚本。一个涉及 readTrajectory (或类似)和 DataFiles.writeCSVmatrix 的组合,另一个是 $ %Dymola%\bin\alist -e var1 dsres.mat res.csv
    • 谢谢汉斯。我已经包含了 DataFiles 变体。对于这么多变量,alist 可能不是一个好的选择。
    猜你喜欢
    • 1970-01-01
    • 1970-01-01
    • 2014-02-11
    • 1970-01-01
    • 1970-01-01
    • 1970-01-01
    • 1970-01-01
    • 1970-01-01
    • 2016-11-10
    相关资源
    最近更新 更多