在球拍中转置矩阵（列表列表

Question

我在球拍中有一个列表列表，必须转置它们。

(: transpose ((list-of(list-of %a)) -> (list-of (list-of %a))))

(check-expect (transpose (list (list 1 2 3)
                               (list 4 5 6)))
              (list (list 1 4)
                    (list 2 5)
                    (list 3 6)))

(define transpose
  (lambda (xs)
    (cond
      ((empty? xs)empty)
      ((pair? xs)(make-pair  (make-pair (first(first xs))  (make-pair (first(first(rest xs)))empty)) (transpose (rest(rest xs))))))))

这是我目前的代码。 我认为问题出在递归调用中（如果我错了，请纠正我）。

实际结果是(list (list 1 4))。其余的似乎有点被忽略了。

如果有人知道问题或有提示，那真的会帮助我。

Answer 1

(define (transpose xss)
  (apply map list xss))

如果您像我一样是 Scheme 的新手，您会想知道 apply map list 技巧是如何工作的。 这一切都归结为了解apply 和map。

首先，apply 完成了它的工作。它需要一个函数、一些固定参数和一个参数列表。 它使用固定参数调用函数，后跟扁平列表参数。 所以：

(apply map list '((1 2) (3 4)))
                ^^^^^^^^^^^^^^-- list of arguments
           ^^^^ ---------------- a fixed argument
       ^^^ --------------------- function

评估为：

(map list '(1 2) '(3 4))

注意列表列表是如何变成两个列表的。

现在map 接受一个 N 参数函数和 N 个等长列表。然后它返回一个列表，其中每个元素都是函数的一个应用程序。 例如

(map + '(1 2) '(3 4))

评估为：

(list (+ 1 3) (+ 2 4))

在转置技巧中，函数只是list，所以：

(map list '(1 2) '(3 4))

评估为：

(list (list 1 3) (list 2 4))

第一个list 构造一个列表，因为map 总是返回一个列表，而另外两个是对传递的list 函数的调用。

Answer 2

(define (tr ls)
  (if (empty? (car ls)) empty
 (if (null? ls) empty
     (cons (map car ls) (tr (map cdr ls))))))

Answer 3

for/list 可以按顺序使用来创建带有转置项的列表列表：

(define (transpose_ lol)                    ; lol is list of lists
  (for/list ((i (length (list-ref lol 0)))) ; loop for length of first inner list
    (for/list ((il lol))                    ; for each inner list (il)
      (list-ref il i))))                    ; get its item

测试：

(transpose_ (list (list 1 2 3)
                  (list 4 5 6)))

输出：

'((1 4) (2 5) (3 6))

Answer 4

transpose的最简单定义是：

(define (transpose xss)
  (apply map list xss))

为什么会起作用？

  (apply map list '((a b) (d e))
= (apply map List '((a b) (d e))    ; use List rather than list
= (map List '(a b) '(d e))
= (list (List 'a 'd) (List 'b e))
= '((a d) (b e))

这里List 用大写字母拼写只是为了显示哪个list 是用户给出的，哪个是map 生成的。

这是一个不太“聪明”的解决方案。它使用第一列 一个矩阵成为转置矩阵的第一行。

(define transpose
  (lambda (xss)
    (cond
      [(empty? xss)         empty]
      [(empty? (first xss)) empty]
      [else                 (define first-column   (map first xss))
                            (define other-columns  (map rest  xss))
                            (cons first-column
                                  (transpose other-columns))])))