Gnuplot 线型

Question

如何在 gnuplot 上绘制不同类型的线条？我要画不同的颜色。我的脚本加入了几个文件，我认为这就是为什么这些行不是破折号的原因。四个中只有两个是虚线。 谢谢 费利佩

#!/usr/bin/gnuplot

set grid
set title 'Estado dos arquivos no BTRIM com peers de comportamento condicionado'
set xlabel 'Tempo discreto'
set ylabel 'Quantidade de arquivos'
set style line 1 lc rgb '#0060ad' lt 1 lw 2 pi -1 ps 1.0
set style line 2 lc rgb '#dd181f' lt 9 lw 2 pi -1 ps 1.0
set style line 3 lc rgb '#29c524' lt 6 lw 2 pi -1 ps 1.0
set style line 4 lc rgb '#7D72F9' lt 7 lw 2 pi -1 ps 1.0
set style line 5 lc rgb '#000000' lt 8 lw 2 pi -1 ps 1.0

set termoption dashed
#set pointintervalbox 0
#set boxwidth 0.1
#set style fill solid

plot '<paste ../00/StatisticNormal.txt ../01/StatisticNormal.txt ../02/StatisticNormal.txt  ../03/StatisticNormal.txt ../04/StatisticNormal.txt ../05/StatisticNormal.txt ../06/StatisticNormal.txt ../07/StatisticNormal.txt ../08/StatisticNormal.txt ../09/StatisticNormal.txt' smooth unique with line ls 1 title 'Normais', \
'<paste ../00/StatisticVogue.txt ../01/StatisticVogue.txt ../02/StatisticVogue.txt ../03/StatisticVogue.txt ../04/StatisticVogue.txt ../05/StatisticVogue.txt ../06/StatisticVogue.txt ../07/StatisticVogue.txt ../08/StatisticVogue.txt ../09/StatisticVogue.txt' smooth unique with line ls 2 title 'na Moda', \
'<paste ../00/StatisticPopular.txt ../01/StatisticPopular.txt ../02/StatisticPopular.txt ../03/StatisticPopular.txt ../04/StatisticPopular.txt ../05/StatisticPopular.txt ../06/StatisticPopular.txt ../07/StatisticPopular.txt ../08/StatisticPopular.txt ../09/StatisticPopular.txt' smooth unique with line ls 3 title 'Populares', \
'<paste ../00/StatisticRarity.txt ../01/StatisticRarity.txt ../02/StatisticRarity.txt ../03/StatisticRarity.txt ../04/StatisticRarity.txt ../05/StatisticRarity.txt ../06/StatisticRarity.txt ../07/StatisticRarity.txt ../08/StatisticRarity.txt ../09/StatisticRarity.txt' smooth unique with line ls 4 title 'Raros'

pause -1

Answer 1

直到版本 4.6

linestyle 的破折号类型由linetype 给出，它也会选择线条颜色，除非您使用linecolor 明确设置另一种颜色。

但是，对虚线的支持取决于所选的终端：

1. 有些终端不支持虚线，比如png（使用libgd）
2. 其他终端，如pngcairo，支持虚线，但默认禁用。要启用它，请使用 set termoption dashed 或 set terminal pngcairo dashed ...。
3. 终端之间的确切破折号模式不同。要查看定义的linetype，请使用test 命令：

跑步

set terminal pngcairo dashed
set output 'test.png'
test
set output

给予：

而postscript 终端显示不同的破折号模式：

set terminal postscript eps color colortext
set output 'test.eps'
test
set output

5.0 版

从 5.0 版开始，引入了以下与线型、虚线图案和线条颜色相关的更改：

• 引入了新的dashtype 参数：

  要获得预定义的破折号模式，请使用例如

  plot x dashtype 2
  

  您还可以指定自定义破折号模式，例如

  plot x dashtype (3,5,10,5),\
       2*x dashtype '.-_'
  

• 终端选项 dashed 和 solid 被忽略。默认情况下，所有线条都是实心的。要将它们更改为虚线，请使用例如

  set for [i=1:8] linetype i dashtype i
  

• 默认的线条颜色集已更改。您可以使用set colorsequence default|podo|classic 在三种不同的颜色集之间进行选择：