面板数据中的返回计算不正确

Question

我目前正在使用 Stata 中的面板数据，并运行以下命令来定义面板：

encode ticker, generate(ticker_n)
xtset ticker_n time

代码是一个字符串（证券交易所上市公司的代码），时间是一个整数，从 930（开市）到 1559（收市）。因此，这里的时间表示证券交易所开市的分钟数。对于股票市场开盘的每一分钟，我们都有在证券交易所上市的所有收盘价。数据样本如下所示：

date        time    open    high    low     close   volume  ticker  ticker_n
09/15/2008  930     33.31   33.31   33.31   33.31   2135    zeus    zeus
09/15/2008  931     32.94   32.94   32.94   32.94   100     zeus    zeus
09/15/2008  930     10.21   10.21   10.21   10.21   4270    bx      bx
09/15/2008  931     10.46   10.5    10.42   10.44   5700    bx      bx

然后，为了计算收益（使用收盘价），我运行以下命令：

gen return = (close - l.close) / l.close

但是，这会导致一个奇怪的错误，即每隔一小时（时间 = 1100、1200、1300 等）根本不计算回报，Stata 只会报告回报的“-”。

现在我假设在定义面板数据时出现了问题，因此 Stata 无法识别 1500 之前的观察值应该是 1459（我假设它寻找 1499？）。

因此，我的问题是，如何正确定义面板数据，以便 Stata 识别出我的时间轴以分钟为单位？我在Stata官方文档中没有找到任何可以帮助我的东西。

Answer 1

确实：你的 time 变量正在严重地搞砸你。如果time 从 1059 到 1100，或从 1159 到 1200，则每一个都是 41 到 Stata 的跳跃。 1100 之前的时间值应该是时间 1099，这不会在您的数据中；因此之前的 1100 等值都将丢失。无论如何，Stata 会看着 1100 并说“哦！那是一个时间，所以之前的时间应该是 1059，我应该使用 1059 的值”。应用时间显示格式不会改变您无法看到您所理解的时间。

您没有解释应该如何将每日日期输入您的分析。这是仅以小时和分钟计的时间的一些技巧。

clear 
input time 
930
931 
959 
1000
1001 
1059
1100  
end 

gen double mytime = dhms(0, floor(time/100), mod(time, 100), 0) 

format mytime %tcHH:MM

gen id = 1 
xtset id mytime, delta(60000)  

list mytime L.mytime, sep(0)  

     +-----------------+
     |               L.|
     | mytime   mytime |
     |-----------------|
  1. |  09:30        . |
  2. |  09:31    09:30 |
  3. |  09:59        . |
  4. |  10:00    09:59 |
  5. |  10:01    10:00 |
  6. |  10:59        . |
  7. |  11:00    10:59 |
     +-----------------+