SQL 代理作业失败时在电子邮件中生成错误完整消息

Question

我有 3 个执行 SSIS 包的 SQL 代理作业。当作业出错时，它会生成一封主题为“作业失败 -”的电子邮件，并且电子邮件中包含“作业失败”的消息。该作业由调度方案调用，运行的最后一步是 Run_'

当我查看作业历史记录时，它没有可见的完整错误消息。有什么方法可以将作业配置为在电子邮件中包含 COMPLETE 错误消息？或者，有没有一种方法可以构建一个存储过程，该过程将在特定作业失败时执行，并查询其中一个系统表（sysjobs）？

我以前从未这样做过，但我想我可以在 sysjobs 表中构建一个触发器，该触发器在特定作业失败时触发，并执行 sp_db_sendmail。我试图避免走这条路。有完成我的任务的最佳方式吗？

Answer 1

一种更好的方法是使用多个作业步骤。

Step1: Execute Package

如果 Step1 失败：

Step2: use T-SQL with sp_db_sendmail

Step2可以通过多种方式进行自定义，例如可以附加上一步ssis包生成的日志。

或者

从作业历史记录中获取错误消息并添加到 sp_db_sendmail Refer。

如果您使用项目部署模型，您可以使用目录做很多事情，例如使用 SP 执行 ssis 包，从日志表中获取错误详细信息。

Answer 2

这是您可以在作业中使用的脚本。它会查找当天失败的所有作业。您可以每天运行一次以查看当天失败的作业。如果您想每 30 分钟左右运行一次，并且只查看在过去一小时内失败的作业，您可以添加一个时间变量。你必须能够使用xp_cmdshell，因为你想使用sp_send_dbmail

declare @filepath nvarchar(100)     --file path where results are stored as csv
declare @filename nvarchar(100)     --file name where results are stored
declare @command nvarchar(4000)     --dynamic sql of bcp command
declare @count int                  --result count
declare @emailList varchar(4000)    --people to email
declare @dt int                     --current date in INT format



set @filepath = '"e:\somefolder\'
set @filename = 'Failures.csv"'
set @emailList = 'email@domain.com; someOtherEmail@domain.com'
set @dt = (select convert(int,replace(convert(date,substring(convert(varchar,getdate()),1,11)),'-','')))

--query to get the jobs that failed and why. Looks for jobs that were executed today.
select
    h.run_date,
    h.run_time,
    h.run_status,
    j.name,
    j.description,
    h.message
from 
    msdb.dbo.sysjobhistory  h
    inner join
    msdb.dbo.sysjobs j on j.job_id = h.job_id
where
    h.run_status = 0
    and h.run_date = @dt

--if there were failures then put them in a csv and email them.
set @count = @@ROWCOUNT

if (select @count) > 0
begin
    set @command = 'bcp "select h.run_date, h.run_status, j.name, j.description, h.message from msdb.dbo.sysjobhistory h inner join msdb.dbo.sysjobs j on j.job_id = h.job_id where h.run_status = 0 and h.run_date = convert(int,''' + convert(varchar,@dt) + ''') " queryout '
    set @command = @command + @filepath + @filename + ' -c -t, -T '----> character data, tab delimtted is default use  -t, for comma ... trusted conn,server instance to connect to
    exec master..xp_cmdshell @command

    exec msdb.dbo.sp_send_dbmail 
                    @profile_name = null,
                    @recipients  = @emailList,
                    @body = 'Attached is the job failure results',  
                    @body_format = 'TEXT',
                    @subject = 'Job Failures',
                    @file_attachments = 'e:\someFolder\Failures.csv'

end