ORACLE SQL：循环遍历表

Question

我有一个包含表名列表的表。 我想一一搜索这些表中的每一个，看看它们是否包含特定元素（主键，在脚本开头指定）。 我想返回该元素存在的所有表的列表（理想情况下是不同的）。 我对这个 PL/SQL“不仅仅是一个查询”的东西还很陌生。所以我提前为你即将看到的残暴尝试道歉，但希望它说明了我的目标：

PROCEDURE CHECK_FOR_ELEMENTS
BEGIN
DECLARE 
ELEMENT_KEY varchar(5):=X78ehryfk;
RNUM_MAX int :=167;

----create output table for script
create or replace table ALL_TABLES CONTAINING_&ELEMENT_KEY 
(ELEMENT_KEY VARCHAR(255), 
TABLE_NAME varchar(255))
/
commit;

---begin loop over rnum;
FOR rnum_counter in 1..&RNUM_MAX
LOOP
--define this statement as variable TABLE_NAME_VAR
select table_name from (select * from (select table_name, rownum as rnum         
from all_tables
where owner = 'RMS'
and table_name like 'ABC%'
and table_name not like '%STG'
and table_name not like '%BKP'
and num_rows>0
order by num_rows desc)
where rnum = rnum_counter
)INTO TABLE_NAME_VAR
;
----run below to collect row, if it exists, from table being searched
SQL_STMT:='INSERT INTO ALL_TABLES CONTAINING_&ELEMENT_KEY 
SELECT distinct key,'||TABLE_NAME_VAR||' as UMF from         
'||TABLE_NAME_VAR|| 
' where key like 'ELEMENT_KEY-%'
execute immediate SQL_STMT;
commit;
---insert row into table created for output

END LOOP
---loop over all tables

END;

我得到的主要错误信息是 TABLE_NAME_VAR 不是动态 SQL 语句中的有效表名。我用谷歌搜索了一下，现在我明白你不能使用变量以这种方式输入表名。

非常感谢任何帮助！ 谢谢！

Answer 1

在这里，我试图为您清理它。如果您仍然遇到错误，请告诉我。

create or replace PROCEDURE CHECK_FOR_ELEMENTS is
    ELEMENT_KEY varchar2(14):='X78ehryfk';
    RNUM_MAX int :=167;
    TABLE_NAME_VAR varchar2(30);
    SQL_STMT varchar2(4000);
BEGIN

----create output table for script
begin
    execute immediate 'drop table ALL_TABLES_WITH_' || element_key;
exception when others then null;
end;
execute immediate 'create table ALL_TABLES_WITH_' || element_key || ' 
(ELEMENT_KEY VARCHAR2(255), -- does this need to be 255 characters?
TABLE_NAME varchar2(30))';

--- implicit cursor loop
FOR rnum_row in (select table_name, rownum as rnum         
    from all_tables
    where owner = 'RMS'
    and table_name like 'ABC%'
    and table_name not like '%STG'
    and table_name not like '%BKP'
    and num_rows>0
    order by num_rows desc)
LOOP
    if rnum_row.rnum > RNUM_MAX 
        then exit;
    end if;

    TABLE_NAME_VAR := rnum_row.table_name;

    ----run below to collect row, if it exists, from table being searched
    SQL_STMT:='INSERT INTO ALL_TABLES_WITH_' || element_key || ' 
    (ELEMENT_KEY, TABLE_NAME)
    SELECT distinct key, :1 as UMF from         
    '||TABLE_NAME_VAR|| 
    ' where key like :2';
    execute immediate SQL_STMT using TABLE_NAME_VAR, element_key || '-%';

    ---insert row into table created for output
END LOOP;
commit; 
---loop over all tables

END CHECK_FOR_ELEMENTS;
/