偏移公式中的Excel最小公式答案

【问题标题】：Excel min formula in offset formula偏移公式中的Excel最小公式
【发布时间】：2023-02-04 05:06:28
【问题描述】：

我正在尝试获取最小值单元格的左单元格值

我试过这个公式。但它不工作

=偏移量（最小值（AB2、AD2、AF2、AH2、AJ2）、0、-1）

求更正这个公式

或者有什么简洁明了的方法吗？

【问题讨论】：

标签： excel excel-formula

【解决方案1】：

使用 Office 365：

=FILTER(HSTACK(AA2,AC2,AE2,AG2,AI2),HSTACK(AB2,AD2,AF2,AH2,AJ2)=MIN(AB2,AD2,AF2,AH2,AJ2))

对于旧版本：

=IF(AB2=MIN(AB2,AD2,AF2,AH2,AJ2),AA2,"")&
 IF(AD2=MIN(AB2,AD2,AF2,AH2,AJ2),AC2,"")&
 IF(AF2=MIN(AB2,AD2,AF2,AH2,AJ2),AE2,"")&
 IF(AH2=MIN(AB2,AD2,AF2,AH2,AJ2),AG2,"")&
 IF(AJ2=MIN(AB2,AD2,AF2,AH2,AJ2),AI2,"")

或者这个数组公式：

=INDEX(AA2:AI2,MATCH(1,(AB2:AJ2=MIN(AB2,AD2,AF2,AH2,AJ2))*(ISEVEN(COLUMN(AB2:AJ2))),0))

这将需要在退出编辑模式时使用 Ctrl-Shift-Enter 而不是 Enter 输入数组。

【讨论】：

我很感激。是否有更好更干净的方法来做到这一点？提前致谢。
@FashionFiestas 如果我能想到一个，我会把它包括在内。
@FashionFiestas 查看我为旧版本添加了不同版本的编辑。

【解决方案2】：

MIN 返回一个值，而不是单元格引用，因此您不能将它用作 OFFSET 的输入。

我不知道有任何内置函数的解决方案可以在不连续的范围内工作。

【讨论】：

我很感激。如果有任何替代公式？谢谢

【解决方案3】：

为了O365之前Excel 版本，假设 AB2,AD2,AF2,AH2,AJ2 范围内的条目是非负的:

=OFFSET(
    INDEX(
        (AB2, AD2, AF2, AH2, AJ2),,,
        MATCH(1, FREQUENCY(0, (AB2, AD2, AF2, AH2, AJ2)), 0)
    ),,-1
)

请注意部分中括号的重要性：

(AB2, AD2, AF2, AH2, AJ2)

【讨论】：