获取值的函数/宏

Question

假设我有一个包含 3 个变量的表：var1、var2、var3 和另一个参考表。

现在我想创建另一个变量：var4; var4 是根据 var1、var2 和 var3 以及参考表计算得出的。

我可以创建一个宏来执行此操作（对于每一行），但我不知道如何将宏（表）中的值传递到结果中。我想知道我们如何通过创建一个函数来获取值而不是宏来做到这一点？

我知道如果我可以创建一个这样的函数（这个函数将包括数据步骤和过程摘要），事情会很简单：

var4 = myfunction(var1, var2, var3).

更新：

我的表格参考是：

age range1 range2 range3
1   10     1       8 
2   0      4       1
3   4      6       1
4   6      5       2
5   10     5       6

所以我希望我的函数变成这样：

var4 = myfunction(var1, var2, var3)，例如 var1 = 2, var2 = 2, var3 = 5:

取range2之和（对应var1 = 2）；从第 2 行到第 5 行（对应于 var2= 2 和 var3 = 5），结果将是：4 + 6 + 5 + 5。

提前致谢。

Answer 1

一种解决方案可能是首先将参考表修改为长格式，每个年龄每个范围编号一行，并将累积范围放在一个新变量中。然后从 var2 到 var3 的总和成为两个累加值之间的差，这在双连接中更容易计算：

* Define input data with parameters;
data have;
input var1 var2 var3;
datalines;
1 1 3
2 2 5
3 1 4
;
run;

* Define reference table;
data ref_table;
input age range1 range2 range3;
datalines;
1  10  1  8 
2  0   4  1
3  4   6  1
4  6   5  2
5  10  5  6
;
run;

* Modify reference table to long format with accumulated ranges;
data mod_ref_table;
   set ref_table;

   * Calculated accumulated values of each range;
   acc_range1 + range1;
   acc_range2 + range2;
   acc_range3 + range3;

   * Output the accumulated values for each range;
   range_no = 1;
   acc_range = acc_range1;
   output;
   range_no = 2;
   acc_range = acc_range2;
   output;
   range_no = 3;
   acc_range = acc_range3;
   output;
   
   keep age range_no acc_range;
run;

* Calculate output;
proc sql;
   create table want as 
      select a.*
            ,case 
               when a.var2 = 1 then c.acc_range
               else c.acc_range - b.acc_range
            end as val4
      from have as a
      left join mod_ref_table as b
         on a.var1 = b.range_no and a.var2-1 = b.age
      left join mod_ref_table as c
         on a.var1 = c.range_no and a.var3 = c.age 
   ;
quit;

Answer 2

Macro returning a value

好的，可以在这里找到解决方案。

无论如何感谢您的支持。