我想使用 vba 代码将数据从另一个工作簿复制到我当前的工作簿

Question

我只在所有列中获得相同的值。这是我的代码，请帮助我进行更改。我想使用以下代码将工作表 1 中的值复制到工作表 2，但它只允许我在所有列中粘贴相同的值。我知道必须对最后一行做些什么。但不确定它是什么。

Private Sub Btn_load_data_file_Click()
   Dim FileLocation As String
   Dim LastRow As Long
   Dim wb As Workbook
   Set wb = ActiveWorkbook
    
    FileLocation = Application.GetOpenFilename
    If FileLocation = "False" Then
        Beep
        Exit Sub
    End If
    
    Application.ScreenUpdating = False
    Set ImportWorkbook = Workbooks.Open(Filename:=FileLocation)
    LastRow = ImportWorkbook.Worksheets("Projects").Range("A7").End(xlDown).row
    curr_lrow = wb.Worksheets("Projects").Range("A5").End(xlDown).row
    
    'Copy range to clipboard
    ImportWorkbook.Worksheets("Projects").Range("B7", "B" & LastRow).Copy
    ImportWorkbook.Worksheets("Projects").Range("C7", "C" & LastRow).Copy
    'PasteSpecial to paste values, formulas, formats, etc.
    wb.Worksheets("Projects").Range("A" & LastRow).PasteSpecial Paste:=xlPasteValues
    wb.Worksheets("Projects").Range("C" & LastRow).PasteSpecial Paste:=xlPasteValues
  
End Sub

Answer 1

尝试这样的事情：

Private Sub Btn_load_data_file_Click()
    
    Dim FileLocation As String
    Dim LastRow As Long, wsPaste As Worksheet, curr_lrow As Long
    Dim wb As Workbook, ImportWorkbook As Workbook, wsImport As Worksheet
    
    FileLocation = Application.GetOpenFilename
    If FileLocation = "False" Then
        Beep
        Exit Sub
    End If
    
    Set wb = ActiveWorkbook
    Set wsPaste = wb.Worksheets("Projects")
    
    Application.ScreenUpdating = False
    Set ImportWorkbook = Workbooks.Open(Filename:=FileLocation)
    Set wsImport = ImportWorkbook.Worksheets("Projects")
    
    LastRow = wsImport.Cells(Rows.Count, "A").End(xlUp).Row + 1 'safer than .End(xlDown)...
    curr_lrow = wsPaste.Cells(Rows.Count, "A").End(xlUp).Row + 1
    
    CopyValues wsImport.Range("B7:B" & LastRow), wsPaste.Range("A" & curr_lrow)
    CopyValues wsImport.Range("C7:C" & LastRow), wsPaste.Range("C" & curr_lrow)
    
    ImportWorkbook.Close False
   
End Sub

'Copy values from `rngFrom` to `rngTo`
Sub CopyValues(rngFrom As Range, rngTo As Range)
    With rngFrom
        rngTo.Cells(1).Resize(.Rows.Count, .Columns.Count).Value = .Value
    End With
End Sub