DataAdapter 在到达“结束使用”之前被处理

Question

我知道我应该始终处置 DataAdapter 实例。在大多数情况下，我会在关闭连接后立即处理它，但在用户将修改 DataTable 项目（显示在 ListBox 或 DataGridView 中）的情况下，我会创建 DataAdapter，使用它来填充 DataTable，但不要处理它直到用户点击调用DataAdapter.Update(DataTable) 的Save...不是我的主要问题，但这是正确的方法吗？

回到主要问题，我有这两个功能：

Public Function LoadCompaniesDT(ByRef dtCompanies As DataTable) As Boolean
    Using daCompanies As MySqlDataAdapter = Nothing
        Return LoadCompaniesDT(daCompanies, dtCompanies)
    End Using
End Function

Public Function LoadCompaniesDT(ByRef daCompanies As MySqlDataAdapter, ByRef dtCompanies As DataTable) As Boolean
    Dim sql As String = "SELECT * FROM companies"
    Return LoadDT(daCompanies, dtCompanies, sql, Res.CompaniesFailedMsgBody)
End Function

他们习惯于调用 LoadDT 来填充 DataTable，因此我可以选择是否传递 DataAdapter。

现在我对一些事情感到困惑：当使用第一个 LoadCompaniesDT 函数时，daCompanies 在到达 End Using 之前就被释放了。像这样：

Public Function LoadCompaniesDT(ByRef dtCompanies As DataTable) As Boolean
    Using daCompanies As MySqlDataAdapter = Nothing
        Dim tmp As Boolean = LoadCompaniesDT(daCompanies, dtCompanies)
        Console.WriteLine(daCompanies Is Nothing) ' ==> True!!
        Return tmp
    End Using
End Function

注意：如果我使用Dim daCompanies 而不是Using daCompanies，那么daCompanies Is Nothing 将返回False。

---

LoadDT功能码：

Private Function LoadDT(ByRef da As MySqlDataAdapter, ByRef dt As DataTable,
                                                      ByVal sqlQuery As String,
                                                      ByVal errorText As String) As Boolean
    Dim connStr As String = String.Format("server={0}; port={1}; user id={2}; password={3}; database={4}",
                                          DbServer, DbServerPort, DbUserName, DbPassword, DatabaseName)
    Dim conn As MySqlConnection = New MySqlConnection(connStr)
    Dim cmd As MySqlCommand = New MySqlCommand

    Try
        conn.Open()

        cmd.CommandType = CommandType.Text
        cmd.CommandText = sqlQuery
        cmd.Connection = conn

        da = New MySqlDataAdapter(cmd)
        dt = New DataTable
        da.Fill(dt)

        Return True
    Catch ex As Exception
        MessageBox.Show(errorText, Res.ServerError, MessageBoxButtons.OK, MessageBoxIcon.Error)
        Return False
    Finally
        cmd.Dispose()
        cmd = Nothing
        conn.Close()
        conn.Dispose()
    End Try
End Function

Answer 1

更新：你是对的，如果在 Using 语句中使用 ByRef 传递的实例，则不会从方法中返回初始化的 MySqlDataAdapter。这些变量是只读的。在 C# 中，您会收到 this 有意义的编译器错误：

错误 CS1657 无法将“daCompanies”作为 ref 或 out 参数传递 因为它是一个“使用变量”

记录在案here:

编译器错误CS1657

不能将“参数”作为参考或输出参数传递，因为“原因” 当变量作为 ref 或 out 参数传递时会发生此错误 在该变量是只读的上下文中。只读上下文 包括 foreach 迭代变量、使用变量和固定 变量。

在 VB.NET 中，您可以这样做（因此编译器会忽略它，这几乎是一个错误），但之后不会初始化该变量。但如下所述，无论如何您都不应该使用这种方法。

---

根据另一个问题：

如果您查看MSDN 上的示例，您会发现微软也没有处理数据适配器。所以真的没有必要。话虽如此，最好的做法是对任何实现 IDisposable 的东西使用 Using 语句。

DataAdapter 不是一个昂贵的对象，它不包含非托管资源（如连接）。因此，无论您需要什么，都可以从中创建一个新实例。而且您不需要处置它，但这是一个实现细节，将来可能会改变或在 DbDataAdapter 的不同实现中发生变化，因此处置它仍然是最佳实践，最好使用 Using-statement。

我不会使用您的方法，因为您将 sql 字符串传递给通常会导致 sql 注入漏洞的方法。而是使用 sql 参数。

例如：

Private Function LoadDT() As DataTable
    Dim tbl As New DataTable()
    'Load connection string from app.config or web.config
    Dim sql As String = "SELECT * FROM companies" ' don't use * but list all columns explicitely
    Using conn As New MySqlConnection(My.Settings.MySqlConnection)
        Using da = New MySqlDataAdapter(sql, conn)
            da.Fill(tbl)
        End Using
    End Using
    Return tbl
End Function

我不会传递errorText ByRef，而是使用像log4net 这样的日志框架。