VBA列出可变数量的项目的所有可能组合（嵌套循环的数量作为变量）

Question

绅士！在列出所有可能的组合时，我无法找出将元素数量定义为变量的方法。我有一个硬编码示例，其中元素数 = 3

'Declare variables
Dim a as long
Dim b as Long
Dim C as Long
Dim ElementsArray  as variant

'Array
ElementsArray = array("1400","1900","2400")

'Loop through combinations
for a = lbound(ElementsArray) to ubound(ElementsArray)
    for B= lbound(ElementsArray) to ubound(ElementsArray)
        for c = lbound(ElementsArray) to ubound(ElementsArray)
        debug.print(ElementsArray(a) & " - " & ElementsArray(b) & " - " & ElementsArray(c))
        next c
    next b
next a

但我正在寻找的是一个代码，其中嵌套的 For 循环的数量可能是一个变量，或者是一些其他方式来排列所有可能的组合。请帮助解决这个问题。

Answer 1

这是递归实现的示例。请注意，您不应该使数组太大，因为您将获得 n 的 n 个解决方案的幂 - 对于 4 个元素，即 256，对于 5 个元素，3'125，对于 6，您将获得 46'656，对于 7 823'543 - 如果程序需要很长时间才能执行，请不要抱怨。当然你需要一种方法来做每个排列的东西。

Option Explicit

Sub test()
    Dim ElementsArray  As Variant
    ElementsArray = Array("1400", "1900", "2400")
    ReDim SolutionArray(LBound(ElementsArray) To UBound(ElementsArray))
    
    recursion ElementsArray, SolutionArray, LBound(ElementsArray)
End Sub

Sub recursion(elements, solution, level As Long)
    Dim i As Long
    For i = LBound(elements) To UBound(elements)
        solution(level) = elements(i)
        If level = UBound(elements) Then
            Debug.Print Join(solution, " - ")
        Else
            recursion elements, solution, level + 1
        End If
    Next i
End Sub

更新：这是结果：