【问题标题】:Create Multiple Records in One Form. Only One Field Changes per Record在一个表单中创建多个记录。每条记录只有一个字段更改
【发布时间】:2016-01-19 15:43:58
【问题描述】:

在我工作的地方,我们从客户那里收到电子仪表,并尝试解决他们遇到的错误。我们一次将收到 4-8 米,它们都有相同的问题、相同的规格、相同的一切,每个米之间唯一不同的是序列号。我希望能够以一种形式输入每个序列号和通用规格以创建多个记录。

这是我为表单准备的图片。我一次只能为一个序列号创建记录,但我想一次完成所有操作,以便更快、更轻松地输入数据。

Meter Entry Form

总结一下,Multiple Meters,所有相同的规格,不同的序列号。我想将它全部输入一个表单并创建多个记录。感谢您为我提供的任何帮助或见解。

-克里斯

【问题讨论】:

  • 什么告诉您的表单您已“完成” - 没有看到“保存”或“添加”按钮。如果您将表单上的控件设置为“未绑定”,并且有一个“保存”按钮,则可以循环遍历每个序列号字段,如果不为空,则将记录保存到数据库中。
  • 使用绑定表单,并在更新前事件中设置具有“固定”内容的字段的 DefaultValue 属性。移动到新记录时,字段将显示默认值。

标签: ms-access vba ms-access-2010 ms-access-2007 ms-access-2013


【解决方案1】:

您可以将一个子表单绑定到存储您的计量记录的表,然后在您的主表单上有一些未绑定的字段,允许您输入将在您的批次记录中重复的信息。您还可以在主窗体上放置另一个未绑定的文本框,以指定您想要包含此重复信息的记录数。

所以在下面的模型中,您可以指定需要多少条记录(红色框),例如10 条记录:

然后您将提供将针对这 10 条记录重复的数据(蓝色框):

然后,您将单击一个按钮,该按钮将创建指定数量的记录,并使用给出的重复信息:

然后只需为您生成的批次中的每条记录填写唯一的序列号。

这是我在“添加”按钮上使用的 VBA:

Private Sub cmdAddRecords_Click()

    batchAdd Me.txtRecords
    Me.tblMeters_sub.Requery

End Sub

...以及它调用的batchAdd 子例程:

Public Sub batchAdd(records As Integer)

    Dim db As DAO.Database
    Dim rs As DAO.Recordset
    Dim i As Integer
    
    Set db = CurrentDb
    Set rs = db.OpenRecordset("tblMeters")

    i = 1

    Do While i <= records
    
        rs.AddNew
        rs!SerialNumber = ""
        rs!MeterFirmware = Me.MeterFirmware
        rs!MeterCatalog = Me.MeterCatalog
        rs!Customer = Me.Customer
        rs!MeterKh = Me.MeterKh
        rs!MeterForm = Me.MeterForm
        rs!MeterType = Me.MeterType
        rs!MeterVoltage = Me.MeterVoltage
        rs.Update
        
        i = i + 1

    Loop
    
    rs.Close
    Set rs = Nothing
    Set db = Nothing

End Sub

Here's a link to the mock-up(如果你想仔细看看)。

更新

响应您关于是否可以过滤子表单以使其不只是成为所有仪表的大列表的查询,您可以在 tblMeters 表中添加另一个字段来获取日期以及您向表中添加记录的时间:

然后您需要在 batchAdd 子代码中添加另一行,将系统时间和日期放在这个新字段中:

...

Do While i <= records

    rs.AddNew
    rs!SerialNumber = ""
    rs!MeterFirmware = Me.MeterFirmware
    rs!MeterCatalog = Me.MeterCatalog
    rs!Customer = Me.Customer
    rs!MeterKh = Me.MeterKh
    rs!MeterForm = Me.MeterForm
    rs!MeterType = Me.MeterType
    rs!MeterVoltage = Me.MeterVoltage
    rs!DateAdded = Now                  ' <-- HERE!
    rs.Update
    
    i = i + 1

Loop

...

然后您需要更改子表单的记录源属性(设计视图 > 选择子表单 > 属性表 > 数据选项卡 > 记录源):

将以下 SQL 放入其中:

SELECT TOP 15 tblMeters.SerialNumber, tblMeters.MeterFirmware, tblMeters.MeterCatalog, 
tblMeters.Customer, tblMeters.MeterType, tblMeters.MeterForm, tblMeters.MeterKh, 
tblMeters.MeterVoltage, tblMeters.DateAdded 
FROM tblMeters 
ORDER BY tblMeters.DateAdded DESC;

...它将按日期/时间字段(最近在顶部)对记录进行排序,然后仅显示这些记录的前 15 条。如果您想要不同数量的记录,请将 TOP 15 位更改为您选择的不同数量。

当您单击“添加”时,您的新批次记录应添加到列表顶部,并且列表应保持最多 15 条记录(或您在 TOP ... 中指定的任何数量)

请注意,当我对此进行测试时,快速单击“添加”按钮几次似乎会导致 sql 不打扰 TOP ... 过滤器,但只要每个“添加”之间有大约一秒钟或更长时间" 点击它似乎工作正常。

希望这会有所帮助。

【讨论】:

  • 感谢马特的所有帮助。我真的很感激。我注意到的一件事是,子表单保留了输入的每一个过去的记录,并且基本上变成了整个仪表列表。当有新的仪表要添加表单时,只需将新条目添加到子表单的底部。我想知道是否有办法清除以前的条目,并且每次我想做一个时只出现新记录入口。我对记录集进行了一些研究,但找不到具体的解释/解决方案,因此如果您能提供帮助,将不胜感激。再次感谢!
  • 克里斯,你可以做几件事之一。如果您的规则是每次打开该表单以添加记录时,您可以使用 Form_Open 事件来查找当前表中的最高“ID”,然后将表单过滤器设置为“[ID] > nnn”
  • @MattHall,一切正常,您的解决方案正是我想要的。我什至能够为标准值合并下拉菜单,以使表单更健壮并更快地输入数据。作为实习生,这只是我自己挑选的一个副项目,因为我看到它需要修复。还没给我的主管看,他会被吹走的。非常感谢您的帮助!
  • 不用担心,很高兴我能帮上忙。我绝不是专家,但是如果您想了解我的想法,请随时给我发电子邮件... matthew.richard.hall@gmail.com
  • 我知道旧线程,但是如果我需要创建固定数量的行,并且我只需要为每个行修改一个“分数”字段,我该怎么做?
猜你喜欢
  • 2022-01-06
  • 1970-01-01
  • 1970-01-01
  • 1970-01-01
  • 1970-01-01
  • 1970-01-01
  • 1970-01-01
  • 1970-01-01
相关资源
最近更新 更多