无法使用 Let 和 Makearray 函数将范围传递给 lambda

Question

回到this 问题，我希望在数组中创建一个运行总计，但在数组的每一行中重新开始

1	2	3	4
5	6	7	8

导致

1	3	6	10
5	11	18	26

一种解决方案是使用 Makearray ，这很好用：

=MAKEARRAY(
    2,
    4,
    LAMBDA(r, c,
        SUM(
            INDEX(sheet1!A1:D2, r, 1) : INDEX(sheet1!A1:D2, r, c)
        )
    )
)

但是，我现在希望更一般地使用 Let 语句来写这个：

=LET(
    range, Sheet1!A1:D2,
    MAKEARRAY(
        rows(range),
        Columns(range),
        LAMBDA(r, c,
            SUM(INDEX(range, r, 1) : INDEX(range, r, c))
        )
    )
)

但它导致

这个非常相似的公式可以正常工作（它不应该解决原始问题，而只是用于测试是否可以在 Let 语句中将范围传递给 lambda）：

=LET(
    range, Sheet1!A1:D2,
    SCAN(0, range, LAMBDA(a, c, a + c + INDEX(range, 1, 1)))
)

相同的代码还可以将范围作为参数传递给 Google 表格中的命名函数。

定义范围作为命名范围也有效。

像这样使用封闭的 Lambda 而不是 Let 有同样的问题：

=LAMBDA(range,
    MAKEARRAY(
        ROWS(range),
        COLUMNS(range),
        LAMBDA(r, c,
            SUM(INDEX(range, r, 1) : INDEX(range, r, c))
        )
    )
)

Makearray 是否存在特定问题，或者是否有其他原因导致失败？

Answer 1

INDEX() >>:<<INDEX() 的构造将在应用于范围时起作用。不是数组AFAIK。会导致这些错误。也许尝试类似：

=LET(range,A1:D2,MAKEARRAY(ROWS(range),COLUMNS(range),LAMBDA(r,c,SUM(INDEX(range,r,SEQUENCE(c))))))

这将类似于您的初始公式的构造。但是，在您提到的链接问题中，您希望将SCAN() 与BYROW() 结合使用。您已经注意到嵌套这些 lambda 辅助函数会导致错误。我只是想向您展示，只需一个 SCAN() 函数即可：

=SCAN(0,A1:D2,LAMBDA(a,b,IF(COLUMN(b)=1,b,a+b)))

或者更简洁：

=SCAN(0,A1:D2,LAMBDA(a,b,a*(COLUMN(b)<>1)+b))

我有点困惑，发现我们可以比较 lambda 结构内的 'b' 变量的行/列。我以前不知道的东西……现在。它确实感觉有点小故障，但现在我们实际上可以对SCAN() 内的BYROW() 助手使用某种变体，并分别对初始数组的每一行进行这些计算。