Kusto 时间范围内的重叠间隔数答案

【问题标题】：Kusto number of overlapping intervals in a time rangeKusto 时间范围内的重叠间隔数
【发布时间】：2022-09-24 05:38:24
【问题描述】：

我正在尝试编写一个 Kusto 查询，该查询需要计算某个日期范围内有多少间隔重叠。这就是我的桌子的样子：

userID |  interval1         | interval2
24     |  21.1.2012 10:40   | 21.1.2012 11:00
25     |  21.1.2012 9:55    | 21.1.2012 10:50

我想考虑由 [min(interval1), max(interval2)] 给出的时间范围，步长为 1s，对于这个间隔的每个实例，我想知道上表中有多少间隔重叠。例如，对于 21.1.2012 10:00，只有一个间隔，但对于 10:45，有两个重叠的间隔。

谢谢

你为什么要那个？
我想知道每秒有多少用户同时访问我的 API
事实上，不仅仅是对某些 API 的并发访问，而是对某些共享资源资源的每个特定时间间隔的并发访问

标签： azure kql

【解决方案1】：

每个 interval1 表示额外用户的会话开始 (+1)。
每个 interval2 表示附加用户的会话结束 (-1)。
累计总和表示活动会话的数量。

解决方案 1（渲染级别）
with (accumulate=True)

let t = (datatable (userID:int,interval1:datetime,interval2:datetime)
[
     24 ,datetime(2012-01-21 10:40) ,datetime(2012-01-21 11:00)
    ,25 ,datetime(2012-01-21 09:55) ,datetime(2012-01-21 10:50)
]);
let from_dttm = datetime(2012-01-21 09:30);
let to_dttm   = datetime(2012-01-21 11:30);
let sessions_starts = (t | project delta =  1, dttm = interval1);
let sessions_ends =   (t | project delta = -1, dttm = interval2);
union sessions_starts, sessions_ends
| make-series delta = sum(delta) on dttm from from_dttm to to_dttm step 1s
| render timechart with (accumulate=True)

Fiddle

解决方案 2（数据级别）
mv-apply + row_cumsum

let t = (datatable (userID:int,interval1:datetime,interval2:datetime)
[
     24 ,datetime(2012-01-21 10:40) ,datetime(2012-01-21 11:00)
    ,25 ,datetime(2012-01-21 09:55) ,datetime(2012-01-21 10:50)
]);
let from_dttm = datetime(2012-01-21 09:30);
let to_dttm   = datetime(2012-01-21 11:30);
let sessions_starts = (t | project delta =  1, dttm = interval1);
let sessions_ends =   (t | project delta = -1, dttm = interval2);
union sessions_starts, sessions_ends
| make-series delta = sum(delta) on dttm from from_dttm to to_dttm step 1s
| mv-apply  delta to typeof(long), dttm to typeof(datetime) on (project active_users = row_cumsum(delta), dttm)
| render timechart with (xcolumn=dttm, ycolumns=active_users)

Fiddle

【讨论】：

刚刚意识到，如果您需要的是渲染级别的解决方案，那么有一种更简单的方法。查看更新的答案

【解决方案2】：

查看 Kusto 文档中的此示例：

https://learn.microsoft.com/en-us/azure/data-explorer/kusto/query/samples?pivots=azuredataexplorer#chart-concurrent-sessions-over-time

X
| mv-expand samples = range(bin(interval1, 1m), interval2, 1m)
| summarize count_userID = count() by bin(todatetime(samples), 1m)

【讨论】：