为不同的电子邮件地址插入选择案例

Question

我的代码可以通过单击按钮保存附件。

我们的货运管理团队希望根据带有附件的客户电子邮件来自哪个电子邮件地址，将其保存在客户特定的文件夹中。 （视情况更改strFolderpath。）

我想使用 select-case 方法来更轻松地进行更改和添加。我尝试了多种更改。

如何为该用例添加 select-case 方法？

我的工作代码：

Sub SaveAttachments()
Dim objOL As Outlook.Application
Dim objMsg As Outlook.MailItem 'Object
Dim objAttachments As Outlook.Attachments
Dim objSelection As Outlook.Selection
Dim i As Long
Dim lngCount As Long
Dim strFile As String
Dim strFolderpath As String
Dim strDeletedFiles As String

' Instantiate an Outlook Application object.
Set objOL = CreateObject("Outlook.Application")

' Call the Namespace to see the sender e-mail address.
Set objNamespace = objOL.GetNamespace("MAPI")

' Get the collection of selected objects.
Set objSelection = objOL.ActiveExplorer.Selection

' Set the Attachment folder.
strFolderpath = "C:\Folder\Test\"

' Check each selected item for attachments. If attachments exist,
' save them to the strFolderPath folder and strip them from the item.
For Each objMsg In objSelection

    ' This code only strips attachments from mail items.
    ' If objMsg.class=olMail Then
    ' Get the Attachments collection of the item.
    Set objAttachments = objMsg.Attachments
    lngCount = objAttachments.Count
    strDeletedFiles = ""

    If lngCount > 0 Then

        ' We need to use a count down loop for removing items
        ' from a collection. Otherwise, the loop counter gets
        ' confused and only every other item is removed.

        For i = lngCount To 1 Step -1

            ' Save attachment before deleting from item.
            ' Get the file name.
            strFile = objAttachments.Item(i).FileName

            ' Combine with the path to the Temp folder.
            strFile = strFolderpath & strFile

            ' Save the attachment as a file.
            objAttachments.Item(i).SaveAsFile strFile

            ' Delete the attachment.
            objAttachments.Item(i).Delete

            'write the save as path to a string to add to the message
            'check for html and use html tags in link
            If objMsg.BodyFormat <> olFormatHTML Then
                strDeletedFiles = strDeletedFiles & vbCrLf & "<file://" & strFile & ">"
            Else
                strDeletedFiles = strDeletedFiles & "<br>" & "<a href='file://" & _
                strFile & "'>" & strFile & "</a>"
            End If

            'Use the MsgBox command to troubleshoot. Remove it from the final code.
            'MsgBox strDeletedFiles

        Next i

        ' Adds the filename string to the message body and save it
        ' Check for HTML body
        If objMsg.BodyFormat <> olFormatHTML Then
            objMsg.Body = vbCrLf & "The file(s) were saved to " & strDeletedFiles & vbCrLf & objMsg.Body
        Else
            objMsg.HTMLBody = "<p>" & "The file(s) were saved to " & strDeletedFiles & "</p>" & objMsg.HTMLBody
        End If
        objMsg.Save
    End If
Next

ExitSub:

Set objAttachments = Nothing
Set objMsg = Nothing
Set objSelection = Nothing
Set objOL = Nothing
Set objNamespace = Nothing
End Sub

Answer 1

您需要将Select Case 放在For Each objMsg 循环内（顺便说一句，如果您在使用Case 语法时遇到困难，也可以使用If 语句）。

For Each objMsg In objSelection
    Select Case True
        Case objMsg.SenderEmailAddress = "example@address.com"
            strFolderpath = "C:\Folder\sender1folder\"
        Case objMsg.SenderEmailAddress like "*domain.com"
            strFolderpath = "C:\Folder\otherfolder\"
        Case Else
            strFolderpath = "C:\Folder\Test\"
    End Select

    'rest of loop carry on here

Answer 2

我想为此使用 select-case 方法以便将来更轻松地进行更改和添加，但我现在卡住了

不必使用 select case 运算符。您需要做的第一件事是在代码中获取发件人的 SMTP 地址，然后您才能决定使用哪个路径。

要获取 SMTP 地址而不是 Exchange 1 (X500)，您可以尝试使用 AddressEntry.GetExchangeUser 方法获取 Exchange 用户，然后尝试检索 ExchangeUser.PrimarySmtpAddress 属性值。

在HowTo: Convert Exchange-based email address into SMTP email address 文章中了解更多信息。

在您检索到 SMTP 地址后，您可以分析内容并选择合适的文件夹来保存附件。