删除选择案例结构中的行

Question

代码什么都不做（调试时不会出现中断）。

例如，当美国的牛仔裤数量 20。这就是它不删除任何行的原因。不过，我的“UI”表中的值是数字。

Sub test()

Dim jeans As Double

Sheets("UI").Activate
last_row = Cells(Rows.Count, "A").End(xlUp).Row

For i = 2 To last_row 

    jeans = Cells(i, 8).Value

    If Cells(i, 3).Value = "US" Then
        Select Case jeans
        Case jeans < 20
            Rows(i).Delete
        Case Else
        End Select

    ElseIf Cells(i, 3).Value = "EU" Then
        Select Case jeans
        Case jeans < 10
            Rows(i).Delete
        Case Else
        End Select
    
    ElseIf Cells(i, 3).Value = "ASIA" Then
        Select Case jeans
        Case jeans < 10
            Rows(i).Delete
        Case Else
        End Select

    Else
        Rows(i).Delete
    End If

Next i

End Sub

Answer 1

根据条件向后循环

• 您需要向后循环，从下到上覆盖所有单元格。
• 当代码什么都不做时，检查您计算最后一行的列中是否有数据，在本例中为列A。

Option Explicit

Sub LoopBackward()

    With ThisWorkbook.Worksheets("UI")
        
        Dim LastRow As Long: LastRow = .Cells(.Rows.Count, "A").End(xlUp).Row
        
        Dim Jeans As Double
        Dim r As Long
        
        For r = LastRow To 2 Step -1
            
            Jeans = .Cells(r, "H").Value
            
            Select Case .Cells(r, "C").Value
            Case "US"
                If Jeans < 20 Then .Rows(r).Delete
            Case "EU", "ASIA"
                If Jeans < 10 Then .Rows(r).Delete
            Case Else
                .Rows(r).Delete
            End Select
        
        Next r
    
    End With

End Sub