在 Perl 中将电子邮件地址打印到文件中

Question

我一直在搜索这个网站和其他网站，以找到完成我需要做的事情的最佳方式，但无济于事。基本上我有一个包含一些姓名和电子邮件地址的文本文件。每个姓名和电子邮件地址都在自己的行中。我需要获取电子邮件地址并将它们打印到另一个文本文件中。到目前为止，我能够打印的只是“未找到电子邮件地址”消息。有什么想法吗？谢谢！！

#!/usr/bin/perl

open(IN, "<contacts.txt") || die("file not found");
#chooses the file to read
open(OUT, ">emailaddresses.txt");
#prints file
$none = "No emails found!";
$line = <IN>;

for ($line)
{
    if ($line =~ /[A-Z0-9._%+-]+@[A-Z0-9.-]+\.[A-Z]{2,4}/g)
    {
        print (OUT $line);
    }
    else
    {
        print (OUT $none);
    }
}

close(IN);
close(OUT);

Answer 1

首先，总是 use strict; use warnings。这有助于编写正确的脚本，并且是调试时非常宝贵的帮助。

另外，使用三参数打开：

open my $fh, "<", $filename or die qq(Can't open "$filename": $!);

我包含了失败的原因 ($!)，这也是一个很好的做法。

读取文件（在打开的文件句柄上）的习惯用法是：

while (<$fh>) {
  chomp;
  # The line is in $_;
}

或

while (defined(my $line = <$fh>)) { chomp $line; ... }

您所做的是将一行读入$line，然后在for 循环中循环该一个项。

（Perl 有一个 context 的概念。像<$fh> 这样的运算符的行为因上下文而异。通常，使用标量变量（$ sigil）强制标量上下文，而@，数组的标志，导致列表上下文。这与 PHP 完全不同。）

我会像这样重写你的代码：

use strict; use warnings;
use feature 'say';
my $regex = qr/[A-Z0-9._%+-]+\@[A-Z0-9.-]+\.[A-Z]{2,4}/i; # emails are case insensitive
my $found = 0;

while (<>) { # use special ARGV filehandle, which usually is STDIN
  while (/($regex)/g) {
    $found++;
    say $1;
  }
}
die "No emails found\n" unless $found;

像perl script.pl <contacts.txt >emailaddresses.txt 一样调用。 shell 是你的朋友，创建可以通过管道传输的程序是很好的设计。

更新

如果您想要对文件名进行硬编码，我们会将上述脚本与我展示的三参数 open 结合起来：

use strict; use warnings; use feature 'say';
use autodie; # does `... or die "Can't open $file: $!"` for me
my $regex = qr/[A-Z0-9._%+-]+\@[A-Z0-9.-]+\.[A-Z]{2,4}/i;
my $found = 0;

my $contact_file = "contacts.txt";
my $email_file   = "emailaddresses.txt";

open my $contact, "<", $contact_file;
open my $email, ">", $email_file;

while (<$contact>) {    # read from the $contact filehandle
  while (/($regex)/g) { # the /g is optional if there is max one address per line
    $found++;
    say {$email} $1;    # print to the $email file handle. {curlies} are optional.
  }
}
die "No emails found\n" unless $found; # error message goes to STDERR, not to the file