在状态栏上以印度尼西亚格式显示日期和月份名称

Question

我正在使用以下代码在 Borland Delphi 7 的状态栏上以我的母语印度尼西亚显示 LongDayName、LongMonthName 和 Year。

但是当我在状态栏中输入FormatDateTime('dddd, dd mmmm yyyy', vDate); 时，出现错误：

[Error] Unit1.pas(47): Undeclared identifier: 'vDate'
[Fatal Error] Project1.dpr(5): Could not compile used unit 'Unit1.pas'

当我使用FormatDateTime('dddd, dd mmmm yyyy', Now); 时，结果仍然是英文：

我如何解决这个问题以在印尼语中显示？

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, ComCtrls;

type
  TForm1 = class(TForm)
    StatusBar1: TStatusBar;
    Timer1: TTimer;
    procedure Timer1Timer(Sender: TObject);
  private
  public
    function Tanggal(vDate: TDateTime): String;
  end;

var
  Form1: TForm1;

implementation

 function TForm1.Tanggal(vDate: TDateTime): String;
var
  Counter: byte;
const
  NamaHari : Array [1..7] of string = ('Minggu','Senin','Selasa','Rabu','Kamis','Jumat','Sabtu');
  NamaBulan: Array [1..12] of String = ('Januari','Februari','Maret','April','Mei','Juni','Juli',
  'Agustus','September','Oktober','November','Desember');
begin
  For Counter := 1 to 7 do
  LongDayNames[Counter]:=NamaHari[Counter];
  For Counter := 1 to 12 do
  LongMonthNames[Counter]:=NamaBulan[Counter];
  Result := FormatdateTime('dddd, dd mmmm yyyy', vDate);
end;

procedure TForm1.Timer1Timer(Sender: TObject);
begin
Statusbar1.Panels[0].Text := FormatDateTime('dddd, dd mmmm yyyy', Now);
end;

end.

Answer 1

你快到了。

FormatDateTime('dddd, dd mmmm yyyy', vDate);

Undeclared identifier: 'vDate' 失败，因为 vDate 不存在 - 它是 Tanggal() 方法中的参数名称，因此在 Timer1Timer 方法中不存在。

其次，您只能在 Timer1Timer 中获得英文结果，因为您从不调用 Tanggal()，这是设置全局格式设置并返回印度尼西亚格式日期字符串的原因。

也就是说，Timer1Timer 根据全局格式设置触发并格式化日期。它永远不会使用您的自定义设置，因为您尚未将它们设置为全局设置。工作代码是：

Statusbar1.Panels[0].Text := Tanggal(Now);

将Now的结果传递给Tanggal()，这里是参数vDate；设置设置；使用它们格式化日期；返回该字符串；并将该字符串设置为状态栏面板。

但是，您不应该每次都设置格式设置（在程序启动时设置一次），或者您应该使用单独的TFormatSettings 变量，这样您就不会覆盖全局变量。然后，您可以将其作为第三个参数传递给FormatDateTime。

Answer 2

当您可以直接从 Windows 获取月份名称时，没有理由对它们进行硬编码：

首先制作一个proceudre来设置月份名称并从FormCreate调用它

procedure SetupMonthDayNames;
var
  I, Day: Integer;
const
  IndonesianLCID = 1057;

begin
  for I := 1 to 12 do
  begin
    ShortMonthNames[I] := GetLocaleStr(IndonesianLCID,  LOCALE_SABBREVMONTHNAME1 + I - 1, ShortMonthNames[I]);
    LongMonthNames[I] := GetLocaleStr(IndonesianLCID,  LOCALE_SMONTHNAME1 + I - 1, LongMonthNames[I]);
  end;

  for I := 1 to 7 do
  begin
    Day := (I + 5) mod 7;
    ShortDayNames[I] := GetLocaleStr(IndonesianLCID,  LOCALE_SABBREVDAYNAME1 + Day, ShortDayNames[I]);
    LongDayNames[I] := GetLocaleStr(IndonesianLCID,  LOCALE_SDAYNAME1 + Day, LongDayNames[I]);
  end;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  SetupMonthDayNames;
end;

然后你可以从你的计时器更新状态栏：

procedure TForm1.Timer1Timer(Sender: TObject);
begin
  Statusbar1.Panels[0].Text := FormatDateTime('dddd, dd mmmm yyyy', Now);
end;

它将是印度尼西亚语。