用 GCC 编译 Ada

Question

我正在尝试使用 gcc -c Calculator.ada 编译此 Calculator.ada 文件并收到错误 warning: Calculator.ada: linker input file unused because linking not done - 我已尝试查找解决方案并下载其他可能为我编译但尚未想到的东西还没出来……

这里是Calculator.ada：

--
-- Integer calculator program.  Takes lines of input consisting of
-- <operator> <number>, and applies each one to a display value.  The
-- display value is printed at each step.  The operator is one of =,
-- +, -, *, /, or ^, which correspond to assign, add, subtract, multiply
-- divide, and raise, respectively.  The display value is initially zero.
-- The program terminates on a input of q.
--
with Text_IO;
with Gnat.Io; use Gnat.Io;
procedure Calc is
   Op: Character;               -- Operation to perform.
   Disp: Integer := 0;          -- Contents of the display.
   In_Val: Integer;             -- Input value used to update the display.
begin
   loop
      -- Print the display.
      Put(Disp);
      New_Line;

      -- Promt the user.
      Put("> ");

      -- Skip leading blanks and read the operation.
      loop
         Get(Op);
         exit when Op /= ' ';
      end loop;

      -- Stop when we're s'posed to.
      exit when Op = 'Q' or Op = 'q';

      -- Read the integer value (skips leading blanks) and discard the
      -- remainder of the line.
      Get(In_Val);
      Text_IO.Skip_Line;

      -- Apply the correct operation.
      case Op is
         when '='      => Disp := In_Val;
         when '+'      => Disp := Disp + In_Val;
         when '-'      => Disp := Disp - In_Val;
         when '*'      => Disp := Disp * In_Val;
         when '/'      => Disp := Disp / In_Val;
         when '^'      => Disp := Disp ** In_Val;
         when '0'..'9' => Put_Line("Please specify an operation.");
         when others   => Put_Line("What is " & Op & "?");
      end case;
   end loop;
end Calc;

对于我为什么无法编译它的任何帮助，我将不胜感激。我可以使用 gcc -c 编译 C 文件，并且读到我可以为 Ada 编译相同的方式。

Answer 1

由于 gcc 仅将 .ads 和 .adb 识别为 Ada 源的文件结尾（如 Eugene 提到的 this link 中所述），您需要明确告诉它您希望将此文件编译为 Ada 源。您可以通过

gcc -x ada -c Calculator.ada

编译器可能会给出类似的警告

Calculator.ada:11:11: warning: file name does not match unit name, should be "calc.adb"

但你可以忽略它。但是，最佳做法是使用 gcc 预期的文件名。

Answer 2

默认情况下，Ada 源文件需要以.ads（对于包规范）或.adb（对于主体）结尾，并且文件名需要匹配它们包含的顶级实体。在您的情况下，您应该使用calc.adb。

如果您有包含多个实体的更复杂的源文件，您可以使用gnatchop tool to rename source files。

在File Naming Topics and Utilities 下，该手册包含更多关于如何在文件系统中表示源代码的文档。