在午夜获取今天的日期和时间并添加到它

Question

是否有 sql 命令可以在午夜获取今天的日期并能够添加分钟数？

Answer 1

现在日期午夜时间：

Select DATEADD(d,0,DATEDIFF(d,0,GETDATE()))

增加 600 分钟：

Select DATEADD(mi,600,DATEDIFF(d,0,GETDATE()))

Answer 2

是的，只需使用 datediff 和 dateadd 函数从任何日期删除时间，然后将一天的小数部分添加到该数字

Declare @aDate DateTime
Set @aDate = getDate()
Declare @Minutes Integer
Set @minutes = 600 -- 10 hours

Select DateAdd(day, DateDiff(day, 0, @aDate), 0) + @minutes / 1440.0  -- 1440 min/day
 -- or You could also use the dateadd again...
Select DateAdd(minute, @minutes , DateAdd(day, DateDiff(day, 0, @aDate), 0))

两个选择都在同一天上午 10:00 返回（或多或少）。这是因为，好吧，看看this SO answer

编辑：添加示例脚本以显示其工作原理：

declare @dtTim datetime = getDate()
declare @today datetime = dateAdd(day, dateDiff(day, 0, @dtTim ), 0)
select  @dtTim, @today

Answer 3

您也可以转换为date 以去除时间部分：

declare @minutes int = 600
declare @start datetime = cast(getdate() as date)
declare @finish datetime = dateadd(mi, @minutes, @start)

虽然，老实说，我不知道它的表现如何与

dateadd(day, datediff(day, 0, getdate()), 0)

Answer 4

死灵法：

最简单/最快的方法是：

SELECT 
    DATEADD(minute, 1, 
        CAST(FLOOR(CAST(CURRENT_TIMESTAMP AS float)) AS datetime)   
    )

或使用 UTC：

SELECT 
    DATEADD(minute, 1, 
        CAST(FLOOR(CAST( GETUTCDATE() AS float)) AS datetime)   
    )

这是可行的，因为在 SQL-server 中，datetime 是一个浮点值，整数部分表示从 01.01.1900 开始的天数，子整数部分表示全天（24 小时）的百分比。

因此，如果您将 (floor) 浮点数向下舍入为整数，您将得到午夜时间。
1900-01-01T00:00:00.000 为 0。

Answer 5

使用以下：

select DATEADD(SECOND, 36000, CAST(CONVERT(VARCHAR(10), GETDATE(), 101) AS datetime))

通过这种方式，您可以调整秒数以精确定位您想要的一天中的任何时间。

有关 SQL Server 中的日期/时间格式，请参阅此内容： SQL Server Date/Time Formatting

Answer 6

我不得不做类似的事情，创建一个程序从前一天的某个时间运行到当天的某个时间这是我所做的，将开始日期设置为前一天的 16:30，基本上减去你不想让它们回到 0 的部分，然后加上你想要的值。

-- Set Start Date to previous day and set start time to 16:30.00.000

SET @StartDate = GetDate()
SET @StartDate = DateAdd(dd,- 1, @StartDate) 
SET @StartDate = DateAdd(hh,- (DatePart(hh,@StartDate))+16, @StartDate) 
SET @StartDate = DateAdd(mi,- (DatePart(mi,@StartDate))+30, @StartDate) 
SET @StartDate = DateAdd(ss,- (DatePart(ss,@StartDate)), @StartDate) 
SET @StartDate = DateAdd(ms,- (DatePart(ms,@StartDate)), @StartDate) 

希望这对某人有所帮助。