使用 Async.Catch 处理进程损坏状态异常

Question

我需要在我的应用程序中了解动态执行的底层组件何时引发进程损坏状态异常，以便我可以记录它，并将组件标记为无法再次加载并使我的进程崩溃。

此组件的执行是异步执行的，我正在使用 Async.Catch 来处理该异常。我尝试了以下代码来测试 Async.Catch 的行为，在我看来 Async.Catch 已挂起。这对我来说是一种不良影响，我怀疑所有 PCSE 都会导致相同的行为。

有人知道如何摆脱这种情况吗？

let a = async {
    System.Threading.Thread.CurrentThread.Abort()
}

let b = async {
    let! m = Async.Catch a
    return match m with
            | Choice1Of2 p -> "hello"
            | Choice2Of2 e -> "Caught: " + e.ToString()
}

Async.RunSynchronously b;;

编辑 1：我找到了指向我使用 HandleProcessCorruptedStateExceptionsAttribute 和 SecurityCriticalAttribute 或使用配置条目 legacyCorruptedState­­ExceptionsPolicy=true 的文档。如果可能的话，我不想使用配置条目。

编辑 2：根据评论中的建议，我修改了 'b' 的 let 绑定如下：

let b = async {
        try
            let! m = Async.Catch a
            return "hello"
        with
            | :? System.Threading.ThreadAbortException as e -> return "Caught: " + e.ToString()
    }

程序仍然挂起，不返回也不抛出。

Answer 1

这是一个棘手的问题 - 在普通函数中，您可以捕获 ThreadAbortException 并做出反应，但您无法真正处理它，因为它会自动重新抛出（最终会杀死线程）。

在 F# 异步工作流中，异常被处理并且 F# 异步运行时存储它以便它可以通过延续来报告它，但是在它有机会这样做之前，异常被 .NET 重新抛出并杀死线程（因此RunSynchronously 挂起）。

问题是 - 要报告异常，F# async 需要进行一些调用。无法在当前线程（正在取消）上进行调用。如果您期待异常，您可以在线程池中开始工作并自己处理。 （F# 无法自动执行此操作，因为开销太大）。

您可以使用以下助手：

type Microsoft.FSharp.Control.Async with
  static member CatchAbort<'R>(f : unit -> 'R) : Async<'R> =
    async { let hndl = new AutoResetEvent(false)
            let result = ref (Choice3Of3())
            ThreadPool.QueueUserWorkItem(fun _ ->
              try 
                result := Choice1Of3 (f())
                hndl.Set() |> ignore
              with 
                | e -> 
                   // This handler runs correctly even for ThreadAbort
                   result := Choice2Of3 e 
                   hndl.Set() |> ignore) |> ignore
            let! _ = Async.AwaitWaitHandle(hndl) 
            match !result with
            | Choice1Of3(res) -> return res
            | Choice2Of3(exn) -> 
                // Wrap or rethrow the exception in some way
                return raise exn
            | Choice3Of3 _ -> return failwith "unexpected case" }

这会在线程池线程上启动指定的函数（不是异步的）。函数完成或抛出后，将结果返回给原线程，原线程可以恢复工作流。

为了调整您的示例，这应该符合预期：

let a = async {
    let! value = Async.CatchAbort(fun () ->
      System.Threading.Thread.CurrentThread.Abort()
      "not aborted")
    return value }

let b = async {
    try let! m = a
        printfn "ok"
    with e -> printfn "Caught: %A" e }

Answer 2

如您所见here - ThreadAbortException 是 CLR 中的特殊异常之一。它似乎很难打破 Asycn-Pattern，所以我想这就是问题所在。

尝试另一个例外，看看是否可行（应该）。