如何在 PL/SQL 函数中使用传递数组答案

【问题标题】：How to use pass an array in PL/SQL function如何在 PL/SQL 函数中使用传递数组
【发布时间】：2011-09-14 09:18:05
【问题描述】：

我是一名 Java 开发人员，对 Oracle PL/SQL 了解有限。请告诉我如何在以下示例中将数组传递给 PL/SQL 函数以及如何调用它。

CREATE OR REPLACE FUNCTION get_employees (pUserId NUMBER)
  RETURN VARCHAR2
IS
  l_text  VARCHAR2(32767) := NULL;
BEGIN
  FOR cur_rec IN (SELECT grp.NAME GROUP_NAME FROM UserGroupRole ugr, Group_ grp WHERE ugr.groupid=grp.groupid and USERID = pUserId) LOOP
    l_text := l_text || ',' || cur_rec.GROUP_NAME;
  END LOOP;
  RETURN LTRIM(l_text, ',');
END;
/

SELECT get_employees(414091) FROM DUAL;

【问题讨论】：

在您给出的示例中，您传入一个 id 并返回一个逗号分隔的字符串。你想做什么？
我们无法将数组从 Java 传递给 PL/SQL 函数。
我想传递一个id数组，而不是传递id，返回类型也应该是字符串数组。

标签： arrays oracle function plsql

【解决方案1】：

您可以创建一个集合类型并将参数作为该类型的实例传递。

SQL> create type num_array as table of number;
  2  /

Type created.

SQL> create or replace function myfun ( arr_in num_array ) return varchar2 is
  2      txt varchar2(1000);
  3  begin
  4      for i in 1..arr_in.count loop
  5          txt := txt || to_char( arr_in(i) ) || ',';
  6      end loop;
  7      return txt;
  8  end;
  9  /

Function created.

SQL> declare
  2    myarray num_array;
  3    mytext  varchar2(1000);
  4  begin
  5    myarray := num_array();
  6    myarray.extend(3);
  7    myarray(1) := 1;
  8    myarray(2) := 5;
  9    myarray(3) := 9;
 10    dbms_output.put_line( myfun( myarray ));
 11  end;
 12  /

1,5,9,

PL/SQL procedure successfully completed.

【讨论】：

谢谢 eaolson，作为后续，请告诉我如何返回数组。
@michealmarquiz 同上。实例化一个数组。返回数组而不是返回txt。