在 Inno Setup 中显示从下载的 ZIP 文件中提取的许可证

Question

如何将在[Code] 部分下载然后在[Run] 部分解压缩的文件用作要安装的文件？

这是我的代码。问题是，我希望在下载完成后提取 zip 文件。我认为我的代码中没有这个。因为当我输入这个时，我得到一个错误：

在

[Setup]
LicenseFile={tmp}\apache-tomcat-9.0.0.M13\LICENSE
InfoBeforeFile={tmp}\apache-tomcat-9.0.0.M13\NOTICE
InfoAfterFile={tmp}\apache-tomcat-9.0.0.M13\RELEASE-NOTES

下

[Files]
Source: "{tmp}\apache-tomcat-9.0.0.M13\bin\tomcat9.exe"; DestDir: "{app}"; Flags: ignoreversion
Source: "C:\Users\...\apache-tomcat-9.0.0.M13\*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs createallsubdirs

我收到编译错误，例如文件不存在。

如何使用我下载并提取的文件作为许可证和发行说明？

我不确定 .zip 文件是否在我想要提取的阶段被提取。这是我根据这些问题编译的代码：

• Is there a way to extract .zip files in Inno Setup after a certain page is done?
• Running a program after it is downloaded in Code section in Inno Setup

#include <idp.iss>

[Setup]
LicenseFile=C:\..\Desktop\x64\apache-tomcat-9.0.0.M13\LICENSE
InfoBeforeFile=C:\...\x64\apache-tomcat-9.0.0.M13\NOTICE
InfoAfterFile=C:\...\x64\apache-tomcat-9.0.0.M13\RELEASE-NOTES
DisableWelcomePage=no

[Files]
Source: "C:\...\x64\apache-tomcat-9.0.0.M13\*"; DestDir: "{app}"; Flags: ignoreversion recursesubdirs createallsubdirs
Source: "7za.exe"; DestDir: "{tmp}"; Flags: deleteafterinstall;

[Code]

procedure InitializeWizard;
begin
  idpAddFile('http://www-us.apache.org/dist/tomcat/tomcat-9/v9.0.0.M13/bin/apache-tomcat-9.0.0.M13-windows-x64.zip', ExpandConstant('{tmp}\apache-tomcat-9.0.0.M13-windows-x64.zip'));
  idpDownloadAfter(wpWelcome);
end;

[Run]
Filename: {tmp}\7za.exe; Parameters: "x {tmp}\apache-tomcat-9.0.0.M13-windows-x64.zip -o{app}\ * -r -aoa"; Flags: runhidden runascurrentuser;

Answer 1

• 通过设置假许可证文件来启用“许可证”页面。
• 在欢迎页面之后下载带有许可证的 ZIP 文件（您必须明确启用它）。
• 在下载页面的“下一步”按钮处理程序中，解压缩 ZIP 文件，然后加载许可证（您必须对此进行编码，不能使用 [Run] 部分）。

代码使用来自How to get Inno Setup to unzip a file it installed (all as part of the one installation process) 的UnZip 函数，该函数使用Shell.Application。如果您更喜欢外部解压缩应用程序，可以使用Exec 函数在调用UnZip 的同一位置执行它。

#include "idp.iss"

[Setup]
DisableWelcomePage=no
LicenseFile=fake.txt

const
  TomcatVersion = '9.0.0.M13';

var
  TomcatZipPath: string;

procedure InitializeWizard();
var
  TomcatZipUrl: string;
  TomcatZipFile: string;
begin
  TomcatZipFile := 'apache-tomcat-' + TomcatVersion + '-windows-x64.zip';
  TomcatZipPath := ExpandConstant('{tmp}\' + TomcatZipFile);
  TomcatZipUrl :=
    'http://www-us.apache.org/dist/tomcat/tomcat-9/v' + TomcatVersion +
    '/bin/' + TomcatZipFile;
  idpAddFile(TomcatZipUrl, TomcatZipPath);
  idpDownloadAfter(wpWelcome);
end;

function NextButtonClick(CurPageID: Integer): Boolean;
begin
  if CurPageID = IDPForm.Page.ID then
  begin
    idpShowDetails(False);
    IDPForm.DetailsButton.Visible := False;

    WizardForm.NextButton.Enabled := False;
    WizardForm.BackButton.Visible := False;
    WizardForm.CancelButton.Enabled := False;
    try
      IDPForm.TotalProgressLabel.Caption := 'Extracting files...';
      UnZip(TomcatZipPath, ExpandConstant('{tmp}'));
    finally
      WizardForm.BackButton.Visible := True;
      WizardForm.NextButton.Enabled := True;
      WizardForm.CancelButton.Enabled := True;
    end;

    WizardForm.LicenseMemo.Lines.LoadFromFile(
      ExpandConstant('{tmp}\apache-tomcat-9.0.0.M13\LICENSE'));
  end;

  Result := True;
end;