我已经为 PLSQL 异常处理程序编写了代码，但它仍然没有通过 HackerRank 中的测试用例

Question

编写一个 PLSQL 块来获取分配给 EMP 表中员工的不同部门 ID。部门详细信息，例如部门名称和所有需要从部门表中检索。此处不遵循 SQL 完整性约束，因此您可能会发现 DEPT 表中不可用的记录。确保处理所有必需的异常以处理这些记录。

架构详细信息是：

TABLE NAME         COLUMN NAMES
------------       -------------------------------------------------
DEPT               DEPT_HEAD, DEPT_ID, DEPT_NAME

EMP                DEPT_ID, EMP_ACTIVEFROM, EMP_DOB, EMP_FNAME, EMP_ID, EMP_LNAME, 
                           EMP_SAL, EMP_STATUS, EMP_TERMINATIONDATE, LOC_ID, MGR_ID

我已经编写了代码，但每次运行时，输出都与问题中的要求相似，但未通过测试用例。

Question screenshot

Test Case error message

我的代码：

SET SERVEROUTPUT ON
DECLARE
    l_dept_name dept.dept_name%type;
BEGIN
    for cur_r in(select distinct e.dept_id from EMP e)
    loop
        begin
            select d.dept_name into l_dept_name from DEPT d where d.dept_id = cur_r.dept_id;
            dbms_output.put_line('Dept ID: '|| cur_r.dept_id||' is '||l_dept_name);
        exception
            when NO_DATA_FOUND then
                dbms_output.put_line('Dept ID: '|| cur_r.dept_id ||' is not a valid ID');
        end;
    end loop;
END;
/
EXIT;

Answer 1

问题是：

编写一个 PL/SQL 块来获取分配给 EMP 表中员工的不同部门 ID。

您只需从EMP 表中获取DEPT_ID 值并检查它们是否有效（即它们存在于DEPT 表中）；您不需要在DEPT 表中打印EMP 表中不存在的任何ID，因此使用FULL OUTER JOIN 是错误的。

---

在光标中使用LEFT OUTER JOIN：

SET SERVEROUTPUT ON;

BEGIN
  FOR r IN (SELECT DISTINCT
                   e.dept_id,
                   d.dept_name
            FROM   EMP e
                   LEFT OUTER JOIN DEPT d
                   ON e.dept_id = d.dept_id)
  LOOP
    IF r.dept_name IS NULL THEN
      DBMS_OUTPUT.PUT_LINE( 'Dept_ID :'||r.dept_id|| ' is not a valid ID');
    ELSE
      DBMS_OUTPUT.PUT_LINE( 'Dept_ID :'||r.dept_id|| ' is '||r.dept_name);
    END IF;
  END LOOP;
END;
/

另外，请注意格式化输出，使其与预期输出匹配。

其中，对于样本数据：

CREATE TABLE dept (dept_id, dept_name) AS
SELECT 1, 'Dept_name1' FROM DUAL UNION ALL
SELECT 2, 'Dept_name2' FROM DUAL UNION ALL
SELECT 4, 'Dept_name4' FROM DUAL;

CREATE TABLE emp (emp_id, dept_id) AS
SELECT 1, 1 FROM DUAL UNION ALL
SELECT 2, 1 FROM DUAL UNION ALL
SELECT 3, 3 FROM DUAL UNION ALL
SELECT 4, 4 FROM DUAL UNION ALL
SELECT 5, 5 FROM DUAL UNION ALL
SELECT 6, 5 FROM DUAL;

输出：

Dept_ID :1 is Dept_name1
Dept_ID :4 is Dept_name4
Dept_ID :3 is not a valid ID
Dept_ID :5 is not a valid ID

db小提琴here

Answer 2

使用您的 SQL 测试用例以显示结果缺少行：

Fiddle with the procedure, and the corrected procedure

CREATE TABLE dept (dept_id int, dept_name varchar2(10));

CREATE TABLE emp  (dept_id int);

BEGIN
INSERT INTO dept VALUES (1, 'd1');
INSERT INTO dept VALUES (3, 'd3');
INSERT INTO emp VALUES (1);
INSERT INTO emp VALUES (2);
END;
/

SELECT dept.dept_id, dept.dept_name, emp.dept_id AS isExists
  FROM dept FULL JOIN emp ON dept.dept_id = emp.dept_id
;

-- The original procedure, with missing results:
DECLARE
    l_dept_name dept.dept_name%type;
BEGIN
    for cur_r in(select distinct e.dept_id from EMP e)
    loop
        begin
            select d.dept_name into l_dept_name from DEPT d where d.dept_id = cur_r.dept_id;
            dbms_output.put_line('Dept ID: '|| cur_r.dept_id||' is '||l_dept_name);
        exception
            when NO_DATA_FOUND then
                dbms_output.put_line('Dept ID: '|| cur_r.dept_id ||' is not a valid ID');
        end;
    end loop;
END;
/

结果：

dbms_output:
Dept ID: 2 is not a valid ID
Dept ID: 1 is d1

请注意，此结果中缺少 dept_id = 3。

这就是为什么您需要像 FULL JOIN 这样的东西来检测两种缺失的类型，dept_id 不包含在 emp 和 dept_id 中的 emp 中不存在 dept。

现在更正的程序：

我没有删除不必要的SELECT INTO 语句。这些并不是真正需要的，因为光标包含您需要的所有内容。

-- The new procedure, with all expected results:

DECLARE
    l_dept_name dept.dept_name%type;
BEGIN
    for cur_r in(
        SELECT DISTINCT dept.dept_id, dept.dept_name, emp.dept_id AS isExists
          FROM dept FULL JOIN emp ON dept.dept_id = emp.dept_id
        )
    loop
        begin
            select d.dept_name into l_dept_name from DEPT d where d.dept_id = cur_r.dept_id;
            dbms_output.put_line('Dept ID: '|| cur_r.dept_id||' is '||l_dept_name);
        exception
            when NO_DATA_FOUND then
                dbms_output.put_line('Dept ID: '|| cur_r.isexists ||' is not a valid ID');
        end;
    end loop;
END;
/

正确结果：

dbms_output:
Dept ID: 1 is d1
Dept ID: 2 is not a valid ID
Dept ID: 3 is d3

通知dept_id = 3 在结果中。

如果我们想要保证dept_id order 中的 order，我们可以在游标查询中添加以下内容：

ORDER BY COALESCE(dept.dept_id, isExists)

带有描述的原始答案：

您的尝试未检测到存在与emp 行无关的dept.dept_id 的情况。您的 SQL 仅查找 emp 表引用的 dept_id。

光标只需：

SELECT DISTINCT dept.*
     , emp.dept_id AS isExists
  FROM dept FULL JOIN emp ON dept.dept_id = emp.dept_id
;

这会根据要求提供所有部门详细信息的不同列表，以及指示是否找到相应部门的员工记录的列。

当emp 行引用无效的dept_id 时，dept.dept_id 将为空，结果中的isExists 列包含缺少的dept_id。

FULL JOIN 检测到不在dept 表中的emp.dept_id 和不在emp 表中的dept.dept_id。

测试用例：

Fiddle

WITH emp  (dept_id) AS (SELECT 1 FROM dual UNION SELECT 2 FROM dual)
   , dept (dept_id) AS (SELECT 1 FROM dual UNION SELECT 3 FROM dual)
SELECT dept.dept_id, emp.dept_id AS isExists
  FROM dept FULL JOIN emp ON dept.dept_id = emp.dept_id
;

结果：

DEPT_ID	ISEXISTS
1	1
null	2
3	null