查询某个 reg 键值的数据，并使用“goto”和“if”将输出基于该值

Question

您好，我正在尝试创建一个批处理文件，用于查询注册表项并根据其值启动特定程序。

我尝试了互联网上的各种组合，但我似乎无法获得正确的行为。

基本上，脚本会检查定义当前 DPI 的 regkey。根据该值，将运行两个程序之一（PowerShell 脚本），然后运行 ​​InternetExplorer.Application 窗口，并具有特定的大小限制。

来源：

• REG QUERY use in a batch file with IF/THEN
• Batch File: If registry key's data is equal to

到目前为止，我得到的是：

@echo off
setlocal
set "Key=HKCU\Control Panel\Desktop\WindowMetrics"
set Type=REG_DWORD
set Value=AppliedDPI

set Data=
for /f "tokens=2,3" %%a in ('reg query %Key% /v %Value% 2^>NUL ^| find /i "%Value%"') do (
 set TestType=%%a
 set Data=%%b
)
if /i "%Data%"=="0x60" goto Data_96
if /i "%Data%"=="0xc0" goto Data_192
if /i not "%TestType%"=="%Type%" goto :Data_Missing
goto Data_Undefined

:Data_96
echo Data is "%Data%".
goto 96

:Data_192
echo Data is "%Data%".
goto 192

:Data_Missing
echo Key or value not found.
goto leave

:Data_Undefined
echo No action for data "%Data%" defined.
goto leave

:96
powershell.exe -ExecutionPolicy Unrestricted -File somescript1.ps1
goto leave

:192
powershell.exe -ExecutionPolicy Unrestricted -File somescript2.ps1
goto leave

:leave

但这只是行不通。不断收到“找不到键或值”。 我尝试过的其他示例最终都加载了两个脚本。 我显然设置了错误，但不确定是什么。

Answer 1

有了@Squashman 的解决方案，并且意识到我自己的错误是在“设置”命令之前有空格，该脚本现在可以按预期工作。

Answer 2

在这里，为了您的信息，是一个应该做同样事情的脚本：

@Echo Off
Set "PSS="
For /F "Tokens=1,3" %%A In (
    'Reg Query "HKCU\Control Panel\Desktop\WindowMetrics" /v AppliedDPI'
) Do If /I "%%A"=="AppliedDPI" (If %%B Equ 96 Set PSS=somescript1.ps1
    If %%B Equ 192 Set PSS=somescript2.ps1)
If defined PSS powershell -ExecutionPolicy Unrestricted -File "%PSS%"

它使用了运算符不关心值是十六进制还是十进制这一事实。