使用 ADO 记录集和连接更新相同的 #TEMP 表答案

【问题标题】：Use ADO recordset and connection to update same #TEMP table使用 ADO 记录集和连接更新相同的 #TEMP 表
【发布时间】：2017-02-28 15:20:38
【问题描述】：

在 VBA 中，我尝试使用 ADO 记录集和连接对 SQL Server #TEMP 表执行单独的操作。

我认为在记录集和连接下面的代码中使用相同的会话/范围，因此可以使用任一对象访问#TEMP 表。情况似乎并非如此。记录集似乎可以看到连接创建的#TEMP 表，但连接似乎看不到记录集插入的记录。并且记录集在连接对象尝试删除后不返回任何记录。

我想知道为什么会这样，以及如何才能正确地做到这一点。

编辑：无论我使用本地 #TEMP 表还是全局 ##TEMP 表，下面的代码都会失败。

Dim cn As New adodb.Connection
Dim rst As New adodb.Recordset

'Open Connection.
cn.Open cConnSeasFcst

'Create temp table.
cn.Execute "CREATE TABLE #TEMP (COL1 INT)"

'Open rst.
With rst
    .ActiveConnection = cn
    .CursorLocation = adUseClient
    .CursorType = adOpenDynamic
    .LockType = adLockBatchOptimistic
End With

'Add records to temp table using rst.
rst.Open "#TEMP"
For i = 1 To 5
    rst.AddNew
    rst!COL1 = i
    rst.Update
Next

'Delete records using connection.
cn.Execute "DELETE #TEMP WHERE COL1 IN(2,4)", raff

'Display.
rst.Requery
While Not rst.EOF               ' ##ALWAYS AT EOF. RECORDS ARE NOT RETURNED.##
    Debug.Print rst!COL1
    rst.MoveNext
Wend

最终的记录集重新查询根本不返回任何记录，raff 变量为零——在我看来，连接对象看不到记录集插入的任何记录。

【问题讨论】：

您应该使用##TEMP 为其提供全局范围。
Scope of temporary tables in SQL Server的可能重复
虽然是could be this，但请尝试设置SET NOCOUNT ON;。
@Lankymart 相同的代码因全局 ##TEMP 表而失败。我也试过SET NOCOUNT ON;，但也失败了。
你为什么要使用CursorLocation = adClient？您是否尝试过仅使用 ADODB.Recordset 和默认值，而不是尝试精心设计的光标和锁定组合？您应该首先尝试将代码分解为最简单的形式。

标签： sql-server vba adodb

【解决方案1】：

我认为问题在于您在发出删除语句之前没有关闭记录集。我还更改了锁类型，但这可能是次要问题。这对我有用：

Dim cn As New ADODB.Connection
Dim rst As New ADODB.Recordset
Dim i As Integer

Const connString As String = "Provider=sqloledb;Data Source=yourserver;Initial Catalog=yourdb;Integrated Security=SSPI;"

'Open Connection.
cn.Open connString

'Create temp table.
cn.Execute "CREATE TABLE #TEMP (COL1 INT)"

'Open rst.
With rst
    .ActiveConnection = cn
    .CursorType = adOpenDynamic
    .LockType = adLockOptimistic
End With

'Add records to temp table using rst.
rst.Open "#TEMP"
 For i = 1 To 5
    rst.AddNew
    rst!COL1 = i
    rst.Update
 Next
rst.Close

'Delete records using connection.
cn.Execute "DELETE FROM #TEMP WHERE COL1 IN (2,4)"

'Display
rst.Open "#TEMP"
While Not rst.EOF
    Debug.Print rst!COL1
    rst.MoveNext
Wend
rst.Close

【讨论】：