循环以使用 if 语句放置单元格组合

Question

我有一张工作表，其中 3 个工作表中的所有数据将从单元格 D1 开始放在彼此下方。 在 A 到 C 列中，将放置刚刚粘贴的列中计算出的单元格组合。 例如：

cell A2 will be: D2 & E2
Cell B2 will be: D2 & E2 & if (G2 = "" ; F2 ; G2)
cell C2 will be: D2 & E2 & if (H2 = "" ; if (G2 = "" ; F2 ; G2) ; H2)

当我只有一列要填充时（A 列），我有：

Sub M_snb()
  for each sh in sheets(Array("uitdraai FD", "uitdraai asw", "uitdraai food"))
    sn=sh.cells(1).currentregion.offset(1).columns(1)
    sp=sh.cells(1).currentregion.offset(1)

    for j=1 to ubound(sn)
      sn(j,1)=sp(j,2)&sp(j,3)&sp(j,4)
    next

    sh.cells(1).currentregion.offset(1).columns(1)=sn
  next
End Sub

这工作快速而完美，但使用 CurrentRegion。 我一直在尝试更改此脚本，以便将其用于其他 2 列（B 列和 C 列），但到目前为止，我还没有成功。

当我更改代码的第一行并将单元格（1）更改为单元格（4）时，我看到代码从单元格 D1 开始，这很好。甚至 currentregion.offset(1) 都是正确的。但是当我添加 .columns(1) 时，我收到一个错误。 （我尝试了所有方法，将 .select 放在最后，并逐步扩展代码以查看会发生什么）。

error 438: this property or method are not supported by this object.

我怎样才能以最有效的方式实现我的目标？

（这是基础，我有额外的if 语句（有时，F 列中单元格的值是“Zelfzorg ASW”，必须更改为“Zelfzorg”

我希望有人可以帮助我并提供代码来执行我想要的操作。

我正在尝试尽可能多地学习这一点，但我不明白上面代码中发生了什么

Answer 1

然后根据您的评论尝试此操作。
这比循环更快。

未测试：

Option Explicit
Sub Sample()

Dim ws As Worksheet
Dim lrow As Long

For Each ws in Thisworkbook.Sheets(Array("uitdraai FD", "uitdraai asw", "uitdraai food"))
    With ws
        lrow = .Range("D" & Rows.Count).End(xlUp).Row
        If lrow > 1 Then '~~> checks whether Column D has value other than header
            .Range("A2:A" & lrow).Formula = "=D2&E2"
            .Range("B2:B" & lrow).Formula = "=D2&E2&IF(G2="""",F2,G2)"
            .Range("C2:C" & lrow).Formula = "=D2&E2&IF(H2="""",IF(G2="""",F2,G2),H2)"
            '~~>next line converts formulas to values, if you don't want it, remove it
            .Range("A2:C" & lrow).Value = .Range("A2:C" & lrow).Value 
        End If
    End With
Next
End Sub

这是你正在尝试的吗？
代码所做的是将您的公式放在 A、B 和 C 列中，直到您在 D 列中具有值的位置。
希望这对你有用。
还没来得及测试，如果遇到问题，就评论吧。