我知道这个问题比较老，但我一直在寻找答案，并认为我可以扩展问题的“动态”部分并可能帮助某人。
首先，我构建此解决方案是为了解决几个同事遇到的一个问题，即需要快速转换不稳定的大型数据集。
此解决方案需要创建一个存储过程，因此如果您无法满足需要，请立即停止阅读。
此过程将采用数据透视语句的关键变量，为不同的表、列名和聚合动态创建数据透视语句。静态列用作枢轴的分组依据/身份列（如果不需要，可以从代码中删除，但在枢轴语句中很常见并且是解决原始问题所必需的），枢轴列是最终结果列名将从中生成，值列是聚合将应用于的内容。 Table 参数是包含模式 (schema.tablename) 的表的名称，这部分代码可以使用一些爱，因为它不像我希望的那样干净。它对我有用，因为我的使用不是公开的，而且 sql 注入不是问题。 Aggregate 参数将接受任何标准 sql 聚合 'AVG'、'SUM'、'MAX' 等。代码也默认为 MAX 作为聚合，这不是必需的，但最初构建的受众不了解枢轴，通常使用 max 作为聚合。
让我们从创建存储过程的代码开始。此代码应该适用于所有版本的 SSMS 2005 及更高版本，但我尚未在 2005 或 2016 年对其进行测试，但我不明白为什么它不起作用。
create PROCEDURE [dbo].[USP_DYNAMIC_PIVOT]
(
@STATIC_COLUMN VARCHAR(255),
@PIVOT_COLUMN VARCHAR(255),
@VALUE_COLUMN VARCHAR(255),
@TABLE VARCHAR(255),
@AGGREGATE VARCHAR(20) = null
)
AS
BEGIN
SET NOCOUNT ON;
declare @AVAIABLE_TO_PIVOT NVARCHAR(MAX),
@SQLSTRING NVARCHAR(MAX),
@PIVOT_SQL_STRING NVARCHAR(MAX),
@TEMPVARCOLUMNS NVARCHAR(MAX),
@TABLESQL NVARCHAR(MAX)
if isnull(@AGGREGATE,'') = ''
begin
SET @AGGREGATE = 'MAX'
end
SET @PIVOT_SQL_STRING = 'SELECT top 1 STUFF((SELECT distinct '', '' + CAST(''[''+CONVERT(VARCHAR,'+ @PIVOT_COLUMN+')+'']'' AS VARCHAR(50)) [text()]
FROM '+@TABLE+'
WHERE ISNULL('+@PIVOT_COLUMN+','''') <> ''''
FOR XML PATH(''''), TYPE)
.value(''.'',''NVARCHAR(MAX)''),1,2,'' '') as PIVOT_VALUES
from '+@TABLE+' ma
ORDER BY ' + @PIVOT_COLUMN + ''
declare @TAB AS TABLE(COL NVARCHAR(MAX) )
INSERT INTO @TAB EXEC SP_EXECUTESQL @PIVOT_SQL_STRING, @AVAIABLE_TO_PIVOT
SET @AVAIABLE_TO_PIVOT = (SELECT * FROM @TAB)
SET @TEMPVARCOLUMNS = (SELECT replace(@AVAIABLE_TO_PIVOT,',',' nvarchar(255) null,') + ' nvarchar(255) null')
SET @SQLSTRING = 'DECLARE @RETURN_TABLE TABLE ('+@STATIC_COLUMN+' NVARCHAR(255) NULL,'+@TEMPVARCOLUMNS+')
INSERT INTO @RETURN_TABLE('+@STATIC_COLUMN+','+@AVAIABLE_TO_PIVOT+')
select * from (
SELECT ' + @STATIC_COLUMN + ' , ' + @PIVOT_COLUMN + ', ' + @VALUE_COLUMN + ' FROM '+@TABLE+' ) a
PIVOT
(
'+@AGGREGATE+'('+@VALUE_COLUMN+')
FOR '+@PIVOT_COLUMN+' IN ('+@AVAIABLE_TO_PIVOT+')
) piv
SELECT * FROM @RETURN_TABLE'
EXEC SP_EXECUTESQL @SQLSTRING
END
接下来，我们将为示例准备好数据。我从已接受的答案中获取了数据示例，并添加了几个数据元素以用于此概念验证，以显示聚合更改的各种输出。
create table temp
(
date datetime,
category varchar(3),
amount money
)
insert into temp values ('1/1/2012', 'ABC', 1000.00)
insert into temp values ('1/1/2012', 'ABC', 2000.00) -- added
insert into temp values ('2/1/2012', 'DEF', 500.00)
insert into temp values ('2/1/2012', 'DEF', 1500.00) -- added
insert into temp values ('2/1/2012', 'GHI', 800.00)
insert into temp values ('2/10/2012', 'DEF', 700.00)
insert into temp values ('2/10/2012', 'DEF', 800.00) -- addded
insert into temp values ('3/1/2012', 'ABC', 1100.00)
以下示例显示了不同的执行语句，将不同的聚合显示为一个简单的示例。我没有选择更改静态、数据透视和值列以保持示例简单。您应该可以复制并粘贴代码以自己开始弄乱它
exec [dbo].[USP_DYNAMIC_PIVOT] 'date','category','amount','dbo.temp','sum'
exec [dbo].[USP_DYNAMIC_PIVOT] 'date','category','amount','dbo.temp','max'
exec [dbo].[USP_DYNAMIC_PIVOT] 'date','category','amount','dbo.temp','avg'
exec [dbo].[USP_DYNAMIC_PIVOT] 'date','category','amount','dbo.temp','min'
本次执行分别返回以下数据集。