如何将多个 Excel 图表均匀地放置在一张图表中？

Question

如何将四个图表对象放置在具有四个数据集范围的单个 Excel 图表中？

我在图表表中创建所有四个图表。我正在努力调整第一个图表对象的大小，因为它看起来图表大小是固定的。
如果我在图表工作表中创建图表，它会是固定大小，适合整个屏幕吗？

另外，我尝试使用图表索引选择每个图表，但第一个图表对象没有索引，导致四个图表对象中仅获得三个索引。
该代码不起作用，因为第二个导入图表将是索引 1，它与 ForLoop 索引不匹配。

    For i = 1 To cnt_dataset - 1

        Range((Cells(data_array(i, 1), 21)), (Cells(data_array(i, 2), 22))).Select
        ActiveSheet.Shapes.AddChart.Select
        ActiveChart.ChartType = xlLine
        ActiveChart.ApplyLayout (10)
        ActiveChart.ChartGroups(1).HiLoLines.Select
        Selection.Delete

        If i = 1 Then
            ActiveChart.Location Where:=xlLocationAsNewSheet, Name:="Chart"

        Else
            ActiveChart.Location Where:=xlLocationAsObject, Name:="Chart"
            ActiveSheet.ChartObjects(i).Activate

        End If

        With ActiveChart
            .ChartTitle.Text = "Chart A"
            .Axes(xlValue, xlPrimary).AxisTitle.Text = "y"
            .Axes(xlCategory, xlPrimary).AxisTitle.Text = "x"
            .Axes(xlCategory).Select
        End With

        Selection.TickLabels.NumberFormat = "#,##0"
        ActiveWindow.WindowState = xlMaximized          

    Next i

Answer 1

使用这个简单的数据...

...这是创建空白图表表的简单代码，然后直接在此图表表上制作简单图表。

Sub PutChartsIntoChartSheet()
  Dim ws As Worksheet
  Set ws = ActiveSheet
  Dim rng As Range
  Set rng = ActiveSheet.UsedRange

  Dim cht As Chart
  Set cht = ActiveWorkbook.Charts.Add
  cht.ChartArea.Clear

  Dim rX As Range
  Set rX = rng.Columns(1)

  Dim iCht As Long
  For iCht = 1 To rng.Columns.Count - 1
    Dim rY As Range
    Set rY = rX.Offset(, iCht)

    Dim cht2 As Chart
    Set cht2 = cht.Shapes.AddChart(xlLine).Chart
    cht2.SetSourceData Union(rX, rY)
  Next
End Sub

我没有尝试修饰图表或在图表表上很好地排列它们。

这应该可以正常运行。

Answer 2

当您创建图表工作表时，您看到的图表在图表工作表中，而不是在称为 ChartObject 的容器中。因此，您需要一张空白图表表，并且您需要将所有图表作为 ChartObjects 嵌入到此图表表中。

替换这个位：

    If i = 1 Then
        ActiveChart.Location Where:=xlLocationAsNewSheet, Name:="Chart"

    Else
        ActiveChart.Location Where:=xlLocationAsObject, Name:="Chart"
        ActiveSheet.ChartObjects(i).Activate

    End If

有了这个

    ' create reference to new chart
    Dim cht As Chart
    Set cht = ActiveChart

    If i = 1 Then
        ' add chart sheet and make it blank            
        ActiveWorkbook.Charts.Add
        ActiveChart.Name = "Chart"
        ActiveChart.ChartArea.Clear

    End If
    cht.Location Where:=xlLocationAsObject, Name:="Chart"
    ActiveSheet.ChartObjects(i).Activate