触发器没有运行？

Question

我在插入/更新/删除/之后有一个触发器“。它应该根据 Transaction 表中的交易来计算 Account 表上的 Balance。它在事务表上。我很少遇到余额差异，因此决定添加一些登录信息。它转储插入+删除的表（它们组合成一个表变量）和触发它的 tsql 语句。从我的日志来看，似乎 trigger 没有为某些插入到 Transaction 表中而触发。这会发生吗？是否有任何 TSQL 语句可以在不触发触发器的情况下更改表数据（截断表等除外）？

这里是触发器：

CREATE TRIGGER [dbo].[trg_AccountBalance]
ON [dbo].[tbl_GLTransaction] 
AFTER INSERT, UPDATE, DELETE
AS

set nocount on
begin try
    declare @OldOptions int = @@OPTIONS

    set xact_abort off

    declare @IsDebug bit = 1

    declare @CurrentDateTime datetime = getutcdate()
    declare @TriggerMessage varchar(max), @TriggerId int

    if @IsDebug = 1
    begin

        select @TriggerId = isnull(max(TriggerId), 0) + 1
        from uManageDBLogs.dbo.tbl_TriggerLog

        declare @dbcc_INPUTBUFFER table(EventType nvarchar(30), Parameters Int, EventInfo nvarchar(4000) )  

        declare @my_spid varchar(20) = CAST(@@SPID as varchar(20)) 

        insert @dbcc_INPUTBUFFER  
        exec('DBCC INPUTBUFFER ('+@my_spid+')')

        select @TriggerMessage = replace(EventInfo, '''', '''''') from @dbcc_INPUTBUFFER

        insert into uManageDBLogs.dbo.tbl_TriggerLog (TriggerId, "Message", CreateDate)
        values (@TriggerId, @TriggerMessage, @CurrentDateTime)
    end

    declare @Oper int
    select @Oper = 0 

    -- determine type of sql statement
    if exists (select * from inserted) select @Oper = @Oper + 1
    if exists (select * from deleted) select @Oper = @Oper + 2

    if @IsDebug = 1
    begin
        select @TriggerMessage = '@Oper = ' + convert(varchar, @Oper)

        insert into uManageDBLogs.dbo.tbl_TriggerLog (TriggerId, "Message", CreateDate)
        values (@TriggerId, @TriggerMessage, @CurrentDateTime)
    end

    if @Oper = 0 return -- No data changed

    declare @TomorrowDate date = dateadd(day, 1, convert(date, getdate()))
    declare @CurrentDate date = convert(date, getdate())

    -- transactions from both inserted and deleted tables
    declare @tbl_Trans table (FirmId int, GLAccountId int, 
        AmountDebit money, AmountCredit money, "Status" char(1), TableType char(1))

    declare @tbl_AccountCounters table (FirmId int, GLAccountId int, Balance money) 
    declare @IsChange bit = null

    insert into @tbl_Trans (FirmId, GLAccountId, AmountDebit, AmountCredit, "Status", TableType)
        select FirmId, GLAccountId, AmountDebit, AmountCredit, "Status", 'I'
        from inserted
        union
        select FirmId, GLAccountId, AmountDebit, AmountCredit, "Status", 'D'
        from deleted

        if @IsDebug = 1
        begin
            select @TriggerMessage = (select * from @tbl_Trans for xml path ('tbl_Trans'))

            insert into uManageDBLogs.dbo.tbl_TriggerLog (TriggerId, "Message", CreateDate)
            values (@TriggerId, @TriggerMessage, @CurrentDateTime)
        end

        insert into @tbl_AccountCounters (FirmId, GLAccountId, Balance)
            select FirmId, GLAccountId, 0
            from @tbl_Trans
            group by FirmId, GLAccountId

        if @Oper = 1 or @Oper = 2 -- insert/delete
        begin
            update @tbl_AccountCounters
            set Balance = cnt.TransSum
            from @tbl_AccountCounters as ac join
            (
                select trans.FirmId, trans.GLAccountId, 
                    isnull(sum((trans.AmountDebit - trans.AmountCredit) * iif(trans.TableType = 'I', 1, -1)), 0)  as TransSum
                from @tbl_Trans as trans
                where trans.Status = 'A'
                group by trans.FirmId, trans.GLAccountId
            ) as cnt on ac.FirmId = cnt.FirmId and ac.GLAccountId = cnt.GLAccountId

            select @IsChange = 1
        end
        else
        begin
            if update(AmountDebit) or update(AmountCredit) or update(Status) or update(GLAccountId)
            begin
                update @tbl_AccountCounters
                set Balance = cnt.TransBalance
                from @tbl_AccountCounters as ac join
                    (select trans.FirmId, trans.GLAccountId, isnull(sum(trans.AmountDebit - trans.AmountCredit), 0) as TransBalance
                    from dbo.tbl_GLTransaction as trans
                    where trans."Status" = 'A' and exists (select 1 from @tbl_AccountCounters as ac 
                        where ac.GLAccountId = trans.GLAccountId and ac.FirmId = trans.FirmId)
                    group by trans.FirmId, trans.GLAccountId) as cnt on 
                        ac.FirmId = cnt.FirmId and ac.GLAccountId = cnt.GLAccountId

                select @IsChange = 0
            end
        end

        if @IsDebug = 1
        begin
            select @TriggerMessage = '@IsChange = ' + isnull(convert(varchar, @IsChange), 'null')

            insert into uManageDBLogs.dbo.tbl_TriggerLog (TriggerId, "Message", CreateDate)
            values (@TriggerId, @TriggerMessage, @CurrentDateTime)

            select @TriggerMessage = (select * from @tbl_AccountCounters for xml path ('tbl_AccountCounters'))

            insert into uManageDBLogs.dbo.tbl_TriggerLog (TriggerId, "Message", CreateDate)
            values (@TriggerId, @TriggerMessage, @CurrentDateTime)
        end

        if @IsChange is not null
        begin
            update tbl_GLAccount
            set tbl_GLAccount.Balance = iif(@IsChange = 1, cnt.Balance + acc.Balance, cnt.Balance),
                tbl_GLAccount.LastUpdate = getutcdate(),
                tbl_GLAccount.LastUpdatedBy = 1 
            from @tbl_AccountCounters as cnt join dbo.tbl_GLAccount as acc on
                cnt.FirmId = acc.FirmId and cnt.GLAccountId = acc.GLAccountId
        end
        if (16384 & @OldOptions) = 16384 set xact_abort on
    end try
    begin catch
        declare @ErrorLine varchar(max)
        select @ErrorLine = uManageDb.dbo.udf_GetErrorInfo()

        insert into uManageDb.dbo.tbl_TriggerError ("Name", "Message", CreateDate) 
        values ('AccountingDB..trg_AccountBalance', @ErrorLine, GETUTCDATE())
    end catch

Answer 1

我想我已经找到了。我有这一行：

select .. from inserted 
union 
select .. from deleted

他们以 300 美元的价格插入了 5 个 trans 和 100 美元的 4 个 trans。我的@tbl_Trans 中有 2 条记录（300 和 100）（它在日志中）。这可能是错误。因此，必须记录 hellps 并触发运行。

我将用 union all 替换 union。