当 IDENTITY_INSERT 设置为 ON 时，必须为表中的标识列指定显式值

Question

我的数据库中有名为Table_Stories 和Table_Images 的表，它们通过键连接。我使用我创建的存储过程将值插入其中。

CREATE TABLE [dbo].Table_Stories
(
    [StoryID] INT NOT NULL IDENTITY(1, 1) PRIMARY KEY,
    [ID] INT FOREIGN KEY REFERENCES Table_Users(ID),
    [StoryText] NVARCHAR(120),
    [imgID] INT FOREIGN KEY REFERENCES Table_Images (imgID)
)

代码：

CREATE PROCEDURE UserStory  
    @ID [INT],
    @storyText [NVARCHAR](120),
    @img [VARCHAR](MAX)
AS
BEGIN
    DECLARE @StoryID INT, @ImageID INT;

    INSERT INTO Table_Images ([img]) VALUES (@img)

    SET @ImageID = SCOPE_IDENTITY();

    INSERT INTO Table_Stories ([ID], [StoryText], [imgID]) 
    VALUES (@ID, @storyText, @ImageID)

    SET @StoryID = SCOPE_IDENTITY();

    INSERT INTO Table_Stories ([StoryID]) 
    VALUES (@StoryID)

    INSERT INTO dbo.imagesInStories (StoryID, imgID)
    VALUES (@StoryID, @ImageID);

    SELECT * 
    FROM Table_Stories 
    WHERE StoryID = @StoryID AND imgID = @ImageID;
END

我跑：

exec UserStory 1, 'I welcom you to my trip', 'Chadmie.jpg'

并得到这个错误：

消息 545，级别 16，状态 1，过程 UserStory，第 14 行 [批处理开始行 291]
当 IDENTITY_INSERT 设置为 ON 或复制用户插入 NOT FOR REPLICATION 标识列时，必须为表“Table_Stories”中的标识列指定显式值。

我不明白这个错误是什么意思以及如何解决它。

附言 我无法在此处插入所有 sql 代码（不像我所做的那样），由于无论我尝试修复问题代码做什么，都会显示红色错误，这让我花费了太多时间。

Answer 1

我的建议：

1. 将ID 重命名为UserID - 对于表UserStory，它的名称现在非常混乱
2. 将所有数据修改放入事务中
3. 删除多余的第二次插入到Table_Stories - 我不知道你为什么写它
4. 在 proc 的名称中添加一些动词，使其类似于 EditUserStory 或 UserStory_UPD 或其他任何内容
5. 如果是dbo，请指定对象的架构事件，不要使用select *

例如

CREATE PROCEDURE dbo.UserStory_UPD
    @UserID INT,
    @storyText NVARCHAR(120),
    @img VARCHAR(MAX) -- I assume this is a path or an URL
AS
BEGIN
    DECLARE @StoryID INT, @ImageID INT;

    BEGIN TRY
      /* params validation stuff */

      BEGIN TRAN

      INSERT INTO dbo.Table_Images ([img]) 
      VALUES (@img)

      SET @ImageID = SCOPE_IDENTITY();

      INSERT INTO dbo.Table_Stories ([UserID], [StoryText], [imgID]) 
      VALUES (@UserID, @storyText, @ImageID)

      SET @StoryID = SCOPE_IDENTITY();

      INSERT INTO dbo.imagesInStories (StoryID, imgID)
      VALUES (@StoryID, @ImageID);

      COMMIT TRAN
    END TRY
    BEGIN CATCH
      IF @@TRANCOUNT > 0
        ROLLBACK TRAN
      /* raiserror stuff or THROW */
    END CATCH

    SELECT s.StoryID, s.UserID, s.StoryText, s.ImgID
    FROM dbo.Table_Stories s
    WHERE s.StoryID = @StoryID
END