从它包含的哈希元素的值中找到一个数组元素

Question

我正在尝试对哈希数组@aoh 进行排序，目前我提取某些键的值并对这个列表进行排序。我从每个哈希中提取键 description 的值。

现在我希望能够识别数组中的哪个元素对应于哈希元素的给定值。

我想我需要使用哈希引用，但是怎么做呢？

我的代码示例如下

#!/usr/bin/perl

use warnings;
use strict;

my %h1 = ('description', 'great one');
my %h2 = ('description', 'fool');
my %h3 = ('description', 'easy');
my %h4 = ('description', 'intermediate');
my %h5 = ('description', 'hard');
my %h6 = ('description', 'beauty');
my %h7 = ('description', 'dark');
my %h8 = ('description', 'yellow');
my %h9 = ('description', 'red');

my @aoh = ( %h1, %h2, %h3, %h4, %h5, %h6, %h7, %h8, %h9 );

my @vals;

while ( my ($index, $value) = each @aoh ) {

    if ( $aoh[$index] ne 'description' ) {
        push @vals, $aoh[$index];
    }
}

my @sorted = sort @vals;

printf "@sorted\n";

在一个结果中，我想像这样得到@sorted_aoh：

@sorted_aoh = (
    'description'->'beauty',
    'description'->'dark',
    'description'->'easy',
    'description'->'fool',
    'description'->'great one',
    'description'->'one',
    'description'->'hard',
    'description'->'intermediate',
    'description'->'red',
);

Answer 1

如前所述，您的数组@aoh 不是散列数组，它只是一个标量数据数组。看起来是这样的

(
  "description",
  "great one",
  "description",
  "fool",
  "description",
  "easy",
  "description",
  "intermediate",
  "description",
  "hard",
  "description",
  "beauty",
  "description",
  "dark",
  "description",
  "yellow",
  "description",
  "red",
)

哈希的标识已丢失，数据被扁平化为单个列表。 Perl 使用 references

实现嵌套结构

你没有说你的数据来自哪里，而是从一些单独命名的哈希开始，然后将它们的引用复制到一个数组中，最好直接使用数组的元素，所以$h1{description} 变为 $aoh[0]{description} 等等。

此解决方案以 @aoh 开始，这样构建，因此没有命名哈希。

（顺便说一句，像%h1 和@aoh 这样的名称很差。标识符应该描述它们的内容概念，所以%people 或@sales_figures，而不是数据结构的性质它们是。Perl 中的前导 % 或 @ 无论如何都会告诉你，但同样适用于任何语言的标识符。）

如果您经常发现自己需要在程序中访问与另一个值相对应的值，那么通常最好构建一个单独的散列来存储该关系。在这里，我构建了哈希 %desc_to_index，它将每个哈希的 description 元素的值与找到它的数组的索引相关联

我已经在最后转储了生成的结构，以便您可以看到它包含的内容

use strict;
use warnings 'all';

use List::Util 'max';

my @aoh = (
    { description => 'great one' },
    { description => 'fool' },
    { description => 'easy' },
    { description => 'intermediate' },
    { description => 'hard' },
    { description => 'beauty' },
    { description => 'dark' },
    { description => 'yellow' },
    { description => 'red' },
);

my %desc_to_index = map { $aoh[$_]{description} => $_ } 0 .. $#aoh;

{
    my $len = max map { length } keys %desc_to_index;

    for my $desc ( sort keys %desc_to_index ) {
        printf "%*s => %d\n", $len, $desc, $desc_to_index{$desc};
    }
}

输出

      beauty => 5
        dark => 6
        easy => 2
        fool => 1
   great one => 0
        hard => 4
intermediate => 3
         red => 8
      yellow => 7

我希望您同意构建%desc_to_index 的map 语句简洁明了，但它可能会让您感到困惑。如果你愿意，你可以写一个 for 循环来代替它做同样的事情，像这样

my %desc_to_index;

for my $i ( 0 .. $#aoh ) {
    my $desc = $aoh[$i]{description};
    $desc_to_index{$desc} = $i;
}

产生相同的结果

还要注意你的循环

while ( my ($index, $value) = each @aoh ) { ... }

在数组上使用each，这在此处是不寻常且不必要的。在 Perl 5 v12 之前它也不可用，如果循环过早退出，each 会产生尴尬的错误

您不需要each，因为您从不使用$value 的值，而是更喜欢$aoh[$index]，这更常见。你的循环最好用像这样的简单for 循环来编写

for my $index ( 0 .. $#aoh ) { ... }

Answer 2

以下代码使用哈希引用数组，并根据description键的值对其进行排序。散列变量名称 (\%h1) 之前的反斜杠表示对该散列的引用。 sort 函数使用自定义比较块，查找 perldoc -f sort 了解更多信息，查找 perldoc perlcheat 了解如何使用参考。

        #!/usr/bin/perl
        use warnings;
        use strict;

        my %h1 = ('description', 'greate one');
        my %h2 = ('description', 'fool');
        my %h3 = ('description', 'easy');
        my %h4 = ('description', 'intermediate');
        my %h5 = ('description', 'hard');
        my %h6 = ('description', 'beauty');
        my %h7 = ('description', 'dark');
        my %h8 = ('description', 'yellow');
        my %h9 = ('description', 'red');
        my @aoh = (\%h1, \%h2, \%h3, \%h4, \%h5, \%h6, \%h7, \%h8, \%h9);

        my @sorted = sort { $a->{description} cmp $b->{description} } @aoh;
        use Data::Dumper;
        print Dumper(\@sorted);

Answer 3

如何在 ll hashes 中利用唯一键名

use Data::Dumper;
my %h1 = ('description', 'great one');
my %h2 = ('description', 'fool');
my %h3 = ('description', 'easy');
my %h4 = ('description', 'intermediate');
my %h5 = ('description', 'hard');
my %h6 = ('description', 'beauty');
my %h7 = ('description', 'dark');
my %h8 = ('description', 'yellow');
my %h9 = ('description', 'red');
my @aoh =  sort map { values $_ } (\%h1, \%h2, \%h3, \%h4, \%h5, \%h6, \%h7, \%h8, \%h9);
my @hash = map { {"description" => $_}} @aoh;
print  Dumper(\@hash);