无法使用 MS Access 2007 中的 ListBox 值传递给查询

Question

早上好，

我正在帮助通过 MS Access 中的表单开发界面。我们有一个包含各种用户值的列表框，用户应该能够在 ListBox 中选择多个值，然后按下按钮执行查询，只返回 Car Name 为所选内容的行。

更新 - 感谢这个论坛的一些很好的反馈，主要问题得到了解决。我的次要问题现在无法执行查询。当我尝试时，我收到无法执行查询的错误。

我的按钮代码（作为事件过程）是：

Option Explicit
Private Sub btnSearchCars_Click()
    MsgBox "Starting Sub"
    Call QueryCars.myQuery
    MsgBox "Ending Sub"
End Sub

然后，我的 QueryCars 模块如下所示：

Sub myQuery()
    Dim strWhere As String
    Dim strSQL As String
    Dim varItem As Variant

    For Each varItem in Forms!FormSelect!listCarID.SelectedItems
        strWhere = strWhere & "'" & Forms!FormSelect!listCarID.ItemData(varItem) & "',"
    Next

strWhere = Left(strWhere, Len(strWhere) -1)

    strSQL = "SELECT tblBig.* FROM tblCars INNER JOIN tblBig ON tblCars.Car_ID = tblBig.Car_ID WHERE tblCars.Car_ID IN (" & strWhere & ");"
    DoCmd.RunSQL strSQL

End Sub

我的错误是“A RunSQL requires an argument of an SQL statement”错误。

DoCmd.RunSQL strSQL

如果有人可以提供帮助，我将不胜感激。我要做的就是从用户选择的列表框中获取值，并将它们用作查询中的 WHERE 条件。我整个上午都在搜索各种 SO 和 Access 论坛，但没有找到任何帮助。

谢谢。如果您有任何问题，请告诉我。

Answer 1

这不是我希望给您的完美答案 - 但无法弄清楚如何在 IN 命令中使用参数查询。

我假设您的列表框包含两列数据，CarID 值位于第一列。

主函数称为ProcessQuery，并接受对列表框的引用作为参数：
Public Sub ProcessQuery(myList As ListBox)

然后，您可以从列表框上的事件调用您的代码并将其传递给列表框引用。

Private Sub btnSearchCars_Click()
    ProcessQuery Me.listCarID
End Sub  

ProcessQuery 过程然后查看第一列以获取索引号、构造 SQL、打开生成的记录集并从每条记录中提取信息。

Public Sub ProcessQuery(myList As ListBox)

    Dim vItem As Variant
    Dim IDList As String
    Dim qdf As dao.QueryDef
    Dim rst As dao.Recordset

    For Each vItem In myList.ItemsSelected
        'Column 0 is first column in listbox.
        IDList = IDList & "'" & myList.Column(0, vItem) & "',"
    Next vItem
    'Removes the final ,
    IDList = Left(IDList, Len(IDList) - 1)

    'Create a temporary query definition & open the recordset.
    Set qdf = CurrentDb.CreateQueryDef("", _
        "SELECT tblBig.* FROM tblCars INNER JOIN tblBig ON tblCars.Car_ID = tblBig.Car_ID WHERE tblCars.Car_ID IN (" & IDList & ")")
    Set rst = qdf.OpenRecordset

    'Move through the recordset and output the first two fields from each record
    'to the Immediate window.
    With rst
        If Not (.BOF And .EOF) Then
            .MoveFirst
            Do While Not .EOF
                Debug.Print .Fields(0) & " - " & .Fields(1)
                .MoveNext
            Loop
        End If
    End With

End Sub 

要将查询结果显示为数据表，您可以使用以下内容，但我更喜欢使用带有IN 参数的存储查询。我会试着弄清楚这一点。

Public Sub ProcessQuery(myList As ListBox)

    Dim vItem As Variant
    Dim IDList As String
    Dim qdf As dao.QueryDef
    Dim rst As dao.Recordset

    For Each vItem In myList.ItemsSelected
        'Column 0 is first column in listbox.
        IDList = IDList & "'" & myList.Column(0, vItem) & "',"
    Next vItem
    'Removes the final ,
    IDList = Left(IDList, Len(IDList) - 1)

    'Create a temporary query definition & open the recordset.
    Set qdf = CurrentDb.CreateQueryDef("TempQDF", _
        "SELECT tblBig.* FROM tblCars INNER JOIN tblBig ON tblCars.Car_ID = tblBig.Car_ID WHERE tblCars.Car_ID IN (" & IDList & ")")

    DoCmd.OpenQuery "TempQDF", acViewNormal

End Sub

Answer 2

我建议首先查看正在生成的实际 WHERE 子句...保留一个单独的字符串变量来存储它，然后在生成时将其转储到即时窗口。

我还建议创建一个单独的函数以将列表框中选择的值作为数组返回。比如：

Public Function getListBoxSelection(ctl As Access.ListBox) As Variant
   Dim arr() As Variant
   Dim varItem As Variant, i As Long

   If ctl.ItemsSelected.Count > 0 Then
      ReDim arr(0 To ctl.ItemsSelected.Count - 1)
      i = 0

      For Each varItem In ctl.ItemsSelected
         arr(i) = ctl.ItemData(varItem)
         i = i + 1
      Next varItem

   End If

   getListBoxSelection = arr
End Function

然后，您将在 SQL 生成中调用它。像

whereClause = join(getListBoxSelection(me.listCarID), " AND ")
debug.Print whereClause

qdf.SQL = _
    "select tblBig.* " & _
    "from tblCars " & _
    "inner join tblBig on tblCars.Cat_ID = tblBig.Car_ID " & _
    "where tblCars.Card_ID in (" & whereClause & ")"