在 oracle APEX 邮件正文中选择并显示表格

Question

在oracle APEX 4.2发送邮件时，是否可以在邮件正文中以classic report的方式选择并显示数据库表？

版本：oracle APEX 4.2

示例：SAMPLE FORMAT FOR EMAIL

问候， 文档

Answer 1

是的，您可以通过发送 HTML 电子邮件 - 但您必须自己构建 HTML。例如：

declare
   l_body_text long;
   l_body_html long;
begin
   l_body_html := '<table style="border-collapse: collapse; border: 1px solid black"><tbody>'
                  || '<tr>'
                  || '<th style="background-color: #eef; border: 1px solid black">ENAME</th>'
                  || '<th style="background-color: #eef; border: 1px solid black">DNAME</th></tr>';

   for r in (select ename, dname from emp)
   loop
      l_body_html := l_body_html || '<tr><td style="border: 1px solid black">' 
                     || r.ename || '</td><td style="border: 1px solid black">'
                     || r.dname|| '</td></tr>';
   end loop;
   l_body_html := l_body_html || '</tbody></table>';

   l_body_text := 'Plain text version';

   apex_mail.send
      ( p_to        => 'you@there.com'
      , p_from      => 'me@here.com'
      , p_body      => l_body_text
      , p_body_html => l_body_html
      , p_subj      => 'Your report'
      );
end;

注意：

1. 您需要提供纯文本替代方案，以防收件人无法接收 HTML 电子邮件。
2. 您需要应用任何内联样式 - 您不能引用 CSS 文件。