如果 Excel 工作簿是打开的，那么...... VBA

Question

我怎么能写代码说呢。

    Dim xlApp As Excel.Application
    Dim xlWorkbook As Excel.Workbook
    Dim xlWorksheet As Excel.Worksheet

如果excel 工作簿已经打开，那么......

    Set xlApp = GetObject(, "Excel.Application")

    elseif xlApp is nothing then
    Set xlApp = New Excel.Application
    xlApp.Visible = True
    Set xlWorkbook = xlApp.Workbooks.Open("E:\InspectionCreator\InspectionSheet.xlsx")
End if

我不希望它必须是一个特定的工作簿，就像我在互联网上找不到任何东西的任何工作簿一样。任何帮助都会很棒。

Answer 1

首先尝试使用getobject：如果它抛出错误然后使用createobject：

  Dim xlApp As Excel.Application

  On Error Resume Next
  Set xlApp = GetObject(, "Excel.Application")
  On Error GoTo 0

  If xlApp Is Nothing Then
    Set xlApp = CreateObject("Excel.Application")
    xlApp.Visible = True
  End If

Answer 2

我曾经运行的代码与 Tim 的代码非常相似，直到 Kevin Jones 在 Experts-Exchange 帖子中指出我将在此重复（因为 EE 帖子在付费墙后面）

“请注意，使用 CreateObject 函数通过自动化启动 Excel 时，Excel 不会加载任何加载项或其他通常自动加载的工作簿。这不是启动将要使用的 Excel 会话的好方法由用户。要在不使用 Excel 以外的任何应用程序的自动化的情况下启动 Excel 应用程序实例，必须使用非自动化方式启动 Excel 应用程序。下面的代码说明了执行此操作的步骤。代码首先尝试获得自动化处理现有应用程序实例。如果找不到现有实例，则使用 Shell 命令启动新实例。"

 Dim ExcelApplication As Object
   Dim TimeoutTime As Long

   On Error Resume Next
   Set ExcelApplication = GetObject(, "Excel.Application")
   On Error GoTo 0
   If ExcelApplication Is Nothing Then
       Shell "Excel.exe"
       TimeoutTime = Timer + 5
       On Error Resume Next
       Do
           DoEvents
           Err.Reset
           Set ExcelApplication = GetObject(, "Excel.Application")
       Loop Until Not ExcelApplication Is Nothing Or Timer > TimeoutTime
       On Error GoTo 0
   End If
   If ExcelApplication Is Nothing Then
       MsgBox "Unable to launch Excel."
   Else
       ' Do something with the Excel instance...
   End If

Answer 3

这可能是错误的方向，但这是我过去使用过的东西..

    If Workbooks.Count > 1 Then 'Or in your case = 0
       'Do Something Here'
    Else
       'Do Something Else'
    End If

这样，它会告诉您是否打开了多个工作簿。否则，听起来您正在查看是否有特定的东西是开放的。

希望对您有所帮助。