将 Select 与多个工作簿一起使用时出现运行时错误 1004

Question

我有一个 Excel 工作簿，它从另外两个工作簿中提取数据。 由于数据每小时更改一次，因此对于同一数据，该宏可能每天使用多次。 所以我只想选择这个日期期间的所有以前的数据并想删除它们。 稍后无论如何都会复制数据。 但是只要我想使用

WBSH.Range(Cells(j, "A"), Cells(lastRow - 1, "M")).Select

代码因错误 1004 应用程序定义或对象定义错误而停止。

仅跟随相关部分的代码的 sn-p。 这里有什么问题？

'Set source workbook
Dim currentWb As Workbook
Set currentWb = ThisWorkbook
Set WBSH = currentWb.Sheets("Tracking")

 'Query which data from the tracking files shoud get pulled out to the file
  CheckDate = Application.InputBox(("From which date you want to get data?" & vbCrLf &       "Format: yyyy/mm/dd "), "Tracking data", Format(Date - 1, "yyyy/mm/dd"))

    'states the last entry which is done ; know where to start ; currentWb File
With currentWb.Sheets("Tracking")
    lastRow = .Range("D" & .Rows.Count).End(xlUp).Row
    lastRow = lastRow + 1
End With

'just last 250 entries get checked since not so many entries are made in one week
j = lastRow - 250

'Check if there is already data to the look up date in the analyses sheet and if so deletes these records
Do
    j = j + 1
    'Exit Sub if there is no data to compare to prevent overflow
    If WBSH.Cells(j + 1, "C").Value = "" Then
        Exit Do
    End If
Loop While WBSH.Cells(j, "C").Value < CheckDate
If j <> lastRow - 1 Then
    'WBSH.Range(Cells(j, "A"), Cells(lastRow - 1, "M")).Select
    'Selection.ClearContents
End If

谢谢！

Answer 1

实际上，您不能在未选择/激活的工作表上使用Select 上的Range。 Select 仅适用于活动工作表。

你应该有类似的东西

WBSH.Activate

之前

WBSH.Range(Cells(j, "A"), Cells(lastRow - 1, "M")).Select

WBSH.Range(WBSH.Cells(j, "A"), WBSH.Cells(lastRow - 1, "M")).Select

看这里：Selecting and activating Cells

注意：尽量避免使用 Select

编辑：要清除内容（如 cmets 中所述），您应该使用类似

WBSH.Range(WBSH.Cells(j, "A"), WBSH.Cells(lastRow - 1, "M")).Clear

而不是（我想）

WBSH.Range(Cells(j, "A"), Cells(lastRow - 1, "M")).Clear

因为您范围内的单元格需要被限定。

您可以使用Clear 删除单元格的格式和该单元格中的值，使用ClearContent 仅删除单元格中的值。

注意你可以使用With:

With WBSH
    .Range(.Cells(j, "A"), .Cells(lastRow - 1, "M")).Clear
End With