访问，VBA：Find First 无法正常工作

Question

我希望这对某人来说是一个简单的问题。我有这种方法，它使用两个表单字段来检查表中是否存在记录，然后添加记录或不执行任何操作。所以如果 patient_id 为 100，visit_number 为 1，那么我只会在新记录不存在的情况下添加。

所以，如果 rst.NoMatch 为真 - 添加一条新记录。但是，我无法让它识别重复项。代码如下：

Private Sub add_record_button_Click()
Dim rst As DAO.Recordset
Set rst = Me.RecordsetClone

Dim dbs As DAO.Database
Set dbs = CurrentDb


If IsNull(Form.patient_id) Or IsNull(Form.visit_number) = True Then
    MsgBox "Please fill in both fields."
Else
    rst.FindFirst "[patient_id] = " & Form.patient_id & " And [visit_number] = " & Form.visit_number

    If rst.NoMatch Then

        Set rst = dbs.OpenRecordset("Visits")
        rst.AddNew
        rst!patient_id = Form.patient_id
        rst!visit_number = Form.visit_number
        rst.Update
        MsgBox "New patient visit has been added to the database."
    Else
        MsgBox "That visit already exists."
    End If
    rst.Close
End If
End Sub

我认为我的 FindFirst 行不正确。在数据库中，变量命名为 Patient_id 和 visit_number。在表格中，它们的名称相同。

任何帮助将不胜感激，谢谢。

编辑。

从下面的 cmets 中，我能够使我的逻辑正常工作，但使用了不同的比较功能 Dlookup。

IsNull(DLookup("[patient_id]", "MyTable", "[patient_id] = " & Forms("MyForm").patient_id & " AND [visit_number] = " & Forms("MyForm").visit_number)

最终编辑。

如果我直接使用表单，上面的行可以让一切正常工作，但是如果我将表单放入导航表单 - 它就停止工作了。最终让它在导航表单中工作的字符串如下所示：

If IsNull(DLookup("[patient_id]", "Visits", "[patient_id] = " & Me!patient_id.Value & " AND [visit_number] = " & Me!visit_number.Value)) = True Then

感谢大家的帮助。

Answer 1

没见过Form这样用过，应该可以直接在表单中添加记录，试试吧：

Private Sub add_record_button_Click()

Dim rst As DAO.Recordset
Set rst = Me.RecordsetClone

Dim PatientId As Variant
Dim VisitNumber As Variant

PatientId = Me!patient_id.Value
VisitNumber = Me!visit_number.Value

If IsNull(PatientId) Or IsNull(VisitNumber) Then
    MsgBox "Please fill in both fields."
Else
    rst.FindFirst "[patient_id] = " & PatientId & " And [visit_number] = " & VisitNumber & ""    
    If rst.NoMatch Then
        rst.AddNew
            rst!patient_id.Value = PatientId
            rst!visit_number.Value = VisitNumber
        rst.Update
        MsgBox "New patient visit has been added to the database."
    Else
        MsgBox "That visit already exists."
        Me.Bookmark = rst.Bookmark
    End If
End If

End Sub