VBA：为什么工作表更改事件只触发单个单元格？

Question

如果对任何列逐个单元格进行更改，代码工作正常，但是，如果我一起更改了超过 1 个单元格，则更改不会反映，有人知道为什么吗？

Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Intersect(Target, Range("Data!O:O")) Is Nothing Then                  
        Target.Offset(0, 14) = Now
    ElseIf Not Intersect(Target, Range("Data!F:F")) Is Nothing Then
        If IsEmpty(Target.Value) = False Then
            Target.Offset(0, 21) = Target.Value
        ElseIf IsEmpty(Target.Value) = True Then
            Target.Offset(0, 21) = Target.Offset(0, -1).Value
        End If
    ElseIf Not Intersect(Target, Range("Data!H:H")) Is Nothing Then
        If IsEmpty(Target.Value) = False Then
            Target.Offset(0, 20) = Target.Value
        ElseIf IsEmpty(Target.Value) = True Then
            Target.Offset(0, 20) = Target.Offset(0, -1).Value
        End If
    End If
End Sub

Answer 1

这是 O 列的小演示。如果列中的任何单元格或组单元格发生变化，则日期将记录在相邻单元格中：

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim RangeOfInterest As Range, Intersection As Range, cell As Range
    
    Set RangeOfInterest = Range("O:O")
    Set Intersection = Intersect(Target, RangeOfInterest)
    
    If Intersection Is Nothing Then Exit Sub
    
    Application.EnableEvents = False
        For Each cell In Intersection
            cell.Offset(0, 1).Value = Date
        Next cell
    Application.EnableEvents = True
End Sub

请注意，我们会遍历 O 列中所有更改的单元格。

编辑#1：

正如GSerg 指出的那样，在这种情况下不需要循环：

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim RangeOfInterest As Range, Intersection As Range, cell As Range
    
    Set RangeOfInterest = Range("O:O")
    Set Intersection = Intersect(Target, RangeOfInterest)
    
    If Intersection Is Nothing Then Exit Sub
    
    Application.EnableEvents = False
            Intersection.Offset(0, 1).Value = Date
    Application.EnableEvents = True
End Sub