记录集上的错误，但相同的 SQL 在其他地方工作

Question

错误：“运行时错误 '3061' 参数太少。预期为 2。

我编写了这个简单的函数，它返回为更改的记录数计算的剩余百分比。它应该在用户更新名为“百分比”的字段时发生。我确信下面的代码应该可以工作，但显然有问题。发生就行了：

Set rs = db.OpenRecordset("SELECT Tier1, [Percentage], Tier3 AS Battalion, Month " _
    & "FROM tbl_CustomPercent " _
    & "WHERE (((Tier1)=[Forms]![frmEntry]![cmbImport_T1]) AND ((Month)=[Forms]![frmEntry]![cmbMonth]));", dbOpenSnapshot)

我想知道当使用“百分比”文本框填充表单的“记录源”时，它怎么会失败。

Function RemainingPercentAvailable() As String
Dim db As DAO.Database
Dim rs As DAO.Recordset
Dim strSQL As String


Set db = CurrentDb
Set rs = db.OpenRecordset("SELECT Tier1, [Percentage], Tier3 AS Battalion, Month " _
& "FROM tbl_CustomPercent " _
& "WHERE (((Tier1)=[Forms]![frmEntry]![cmbImport_T1]) AND ((Month)=[Forms]![frmEntry]![cmbMonth]));", dbOpenSnapshot)

Dim CurrentTotal As Single

CurrentTotal = 0

If Not (rs.EOF And rs.BOF) Then
    rs.MoveFirst

    Do Until rs.EOF = True
        CurrentTotal = CurrentTotal + rs!Percentage
        rs.MoveNext
    Loop

End If


RemainingPercentAvailable = "Remaing available: " & Format(1 - CurrentTotal, "0.000%")

Set rs = Nothing
Set db = Nothing

End Function

Answer 1

调整您的代码以使用带有 QueryDef 的 SELECT 语句，提供参数值，然后从 QueryDef 打开记录集。

Dim db As DAO.Database
Dim qdf As DAO.QueryDef
Dim rs As DAO.Recordset
Dim strSQL As String

strSQL = "SELECT Tier1, [Percentage], Tier3 AS Battalion, [Month] " _
    & "FROM tbl_CustomPercent " _
    & "WHERE (((Tier1)=[Forms]![frmEntry]![cmbImport_T1]) AND (([Month])=[Forms]![frmEntry]![cmbMonth]));"

Set db = CurrentDb
Set qdf = db.CreateQueryDef(vbNullString, strSQL )
' supply values for the 2 parameters ...
qdf.Parameters(0).Value = Eval(qdf.Parameters(0).Name)
qdf.Parameters(1).Value = Eval(qdf.Parameters(1).Name)
Set rs = qdf.OpenRecordset

注意：Month 是保留字。尽管该名称之前显然没有引起任何问题，但我将其括在方括号中，因此 db 引擎不会将字段名称与 Month 函数混淆。这可能是一种不必要的预防措施，但很难准确预测保留字何时会产生问题。实际上，如果可能的话，最好完全避免它们。

Answer 2

这是直接在 DAO.Recordset 中调用查询，它工作得很好。
注意同样的 'Set rs = db.OpenRecordset(strSQL, dbOpenDynaset) 这也是一个参数 SQL。 唯一的区别是，我不需要遍历和分析记录集 - 但错误发生在 'Set rs = " 行，所以我无法进一步了解。

Dim rs As DAO.Recordset 暗淡 db 作为 DAO.Database 将 strSQL 调暗为字符串

strSQL = "SELECT Sum(tbl_SP.AFP) AS AFP_TOTAL, tbl_SP.T1_UNIT" _ &“来自 tbl_SP”_ &“按 tbl_SP.T1_UNIT 分组”_ & "HAVING (((tbl_SP.T1_UNIT)='" & strUnit & "'));"

设置 db = CurrentDb 设置 rs = db.OpenRecordset(strSQL, dbOpenDynaset)

AFP_Total = rs!AFP_Total

Answer 3

还有一种更简单的方法可以计算总百分比。

您可以使用 DSum() 函数，而不是循环遍历记录。

注意，如果没有记录，DSum 会返回 Null，因此需要将其包装在 Nz() 中。

只是为了好玩，这是你的函数，但写成一个单一的语句：

    Function RemainingPercentAvailable() As String
    RemainingPercentAvailable = "Remaining available: " & Format(1 - _
        Nz(DSum("Percentage", _
                "tbl_CustomPercent", _
                "Tier1 = " & QString(cmbImport_T1) & _
                " AND [Month] = " & QString(cmbMonth))) _
        , "0.000%")
    End Function

Answer 4

我不建议在 VBA 中构建临时参数化查询，因为它会使代码过于复杂。而且更慢。我更喜欢构建“纯”SQL，它将直接在数据库引擎中运行，而不需要对 Access 进行任何回调。我假设您的函数是在 frmEntry 表单中定义的，并且 cmbImport_T1 和 cmbMonth 是字符串字段。如果它们是数字，则省略 qString()。

这是我的函数版本。它正确处理空记录集的情况。

Function RemainingPercentAvailable() As String
Dim CurrentTotal As Double, q As String
q = "SELECT Percentage" & _
    " FROM tbl_CustomPercent" & _
    " WHERE Tier1 = " & QString(cmbImport_T1) & _
    " AND [Month] = " & QString(cmbMonth)
CurrentTotal = 0
With CurrentDb.OpenRecordset(q)
  While Not .EOF
    CurrentTotal = CurrentTotal + .Fields("Percentage")
    .MoveNext
  Wend
End With
RemainingPercentAvailable = "Remaining available: " & _
                            Format(1 - CurrentTotal, "0.000%")
End Function

' Return string S quoted, with quotes escaped, for building SQL.
Public Function QString(ByVal S As String) As String
   QString = "'" & Replace(S, "'", "''") & "'"
End Function