删除单元格中文本字符串中具有特定编号的行

Question

我有一个包含大约 500 个数据条目的列表，其中一些在单元格中具有相同数字的不同文本。我需要找到所有带有“00000”的行并删除它们。 我需要计算“test2”启动不工作的时间（18:23）并且需要知道它再次工作需要多长时间（18:30）并且error00000消息弄乱了我的公式所以我需要删除所有其中有 error00000 的行。错误消息永远不会相同，但其中的“000000”始终相同。

我不知道如何使用 VBA 代码找到它，因为我只能在单元格中单独找到数字。数据条目可以每周更改，因此应该使用 VBA。 我有一些代码，但是当数字单独存在于单元格中而不是像Error message 00000 这样的句子中时，它可以在线工作，文本总是在变化，数字保持不变。

删除单元格中仅包含数字的行的代码

Private Sub CommandButton1_Click()
    Dim lRow As Long
    Dim iCntr As Long
    lRow = 1000
    For iCntr = lRow To 1 Step -1
        If Cells(iCntr, 5).Value = "1008" Then
            Rows(iCntr).Delete
        End If
    Next
End Sub



03.09.2015 18:30    test2   EXAMPLETEXT blablablalb error000002
03.09.2015 18:25    test2   EXAMPLETEXT blablablalb error000000
03.09.2015 18:23    test2   EXAMPLETEXT blablablalb error000002
03.09.2015 18:30    test1   EXAMPLETEXT blablablalb error000002
03.09.2015 18:25    test1   EXAMPLETEXT blablablalb error000000
03.09.2015 18:23    test1   EXAMPLETEXT blablablalb error000002

Answer 1

尝试运行以下代码来删除过滤的行。在运行代码之前，请确保输入变量 strSearch、strSearchColName 和 strSheetName 的值。

Sub Delete_Rows_Condtionally()
    Dim lastRow As Long
    Dim currentRow As Long
    Dim cellText As String
    Dim strSearch As String
    Dim strSearchColName As String

    strSearch = "000000"
    strSearchColName = "E"
    strSheetName = "tabelle2"

    With ThisWorkbook.Worksheets(strSheetName)

        'Get last row
        lastRow = .Range(strSearchColName & .Rows.Count).End(xlUp).Row
        currentRow = lastRow
        Do While currentRow >= 1
            cellText = .Range(strSearchColName & currentRow).Text
            If (InStr(1, cellText, strSearch)) Then
                .Range(strSearchColName & currentRow).EntireRow.Delete
            Else
                currentRow = currentRow - 1
            End If
        Loop

    End With

End Sub