如果公式及其范围求和的Excel问题

Question

我的工作表中有这个设置：

  A        B     C           D          E        F
1 11-apr   1pm   2pm         START      END      TOTAL
2          2pm   3pm         11-apr     14-apr   8,50 h
3          6pm   7pm         15-apr     25-apr   ....
4          7pm   8pm
5 14-apr   10am  11am
6          12am  12:30am
7          2pm   3pm
8          3pm   5pm
9 15-apr   1pm   3pm
10         6pm   7pm
...

我需要做以下事情：

以 D2 和 E2 为起点，计算 4 月 11 日至 4 月 14 日之间每天花费的小时数，并将总数写入 F2。 我无法修改我的工作表，并且我不想为引用值创建隐藏单元格，因为我不想弄乱我的 Excel 表。

我正在寻找的是，因为我有一些编程技能，所以在 A:A 单元格之间执行一个 for 循环，并从“11-apr”（在本例中为 A1）所在的行开始，一直到我找到了“14-apr”并在第二天单元格之前停止（所以在 A8 处）。我也更喜欢不制作宏，因为它需要在 D 和 E 列方面是动态的。 A中的日期是随机的，所以没有办法提供下一天的到来。

我问你这是否可以在单元格 F2 中的一个公式中实现。

我所做的是寻找参考。 “11-apr”和“14-apr”的行，然后在数组公式中找到哪些单元格不为空（如 INT(A:A<>"") ）并使用返回的数组我想从“11-apr”行直到next-non-empty-cell-after-"14-apr"-row 减 1（直到 "15-apr" row - 1 ），即数组中的下一个非 0（非 FALSE）值 AFTER 行 "14-apr" " 减 1。我将很多公式与 MATCH、INDEX、LARGE 结合起来获取第 n 个元素但没有用。

希望我已经足够清楚了，在此先感谢！

附：我正在使用 Excel for Mac，以防万一知道有用！

Answer 1

这些非易失性公式数组基于@OverflowStacker 方法来识别Target Range，它们使用INDEX 而不是INDIRECT：

FormulaArrays 输入按 CTRL + SHIFT + ENTER 同时，你会看到公式如果输入正确，则包裹在 { 和 } 之间。

这篇文章验证了提供的日期：

=IF( Start > End, "!Err",

这是FormulaArray 用于根据Start 和End 提供的时间获得加法时间：

= SUM(
INDEX( Column.End , MATCH( MIN( IF( Range.Dates >= Start, Range.Dates ) ), Column.Dates , 0 ) ) :
INDEX( Column.End , MATCH( MIN( IF( Range.Dates > End, Range.Dates ) ), Column.Dates , 0 ) - 1 ),
-INDEX( Column.Start , MATCH( MIN( IF( Range.Dates >= Start, Range.Dates ) ), Column.Dates , 0 ) ) :
INDEX( Column.Start , MATCH( MIN( IF( Range.Dates > End, Range.Dates ) ), Column.Dates , 0 ) - 1 ) ) )

Start、End 和 Total 时间可以表示为 TimeSerial 或 Double（例如分别为 12:30 AM 或 0.5）

下表显示了根据所需时间格式使用的公式：

应用公式：

1. 表1显示的时间为TimeSerial

一个。总计为TimeSerial：在I7 中输入此ArrayFormula，然后向下复制（单元格编号格式为[hh]:mm）

= IF( $G7 > $H7, "!Err", SUM(
  INDEX($E:$E, MATCH( MIN( IF( $C$7:$C$27 >= $G7, $C$7:$C$27 ) ),$C:$C, 0 ) ) :
  INDEX($E:$E, MATCH( MIN( IF( $C$7:$C$27 > $H7, $C$7:$C$27 ) ),$C:$C, 0 ) - 1 ),
- INDEX($D:$D, MATCH( MIN( IF( $C$7:$C$27 >= $G7, $C$7:$C$27 ) ),$C:$C, 0 ) ) :
  INDEX($D:$D, MATCH( MIN( IF( $C$7:$C$27 > $H7, $C$7:$C$27 ) ),$C:$C, 0 ) - 1 ) ) )  

b.总计为Double：在J7 中输入此ArrayFormula，然后向下复制（单元格编号格式为0.?? "Hrs."）

= IF( $G7 > $H7, "!Err", 24 * SUM(
  INDEX($E:$E, MATCH( MIN( IF( $C$7:$C$27 >= $G7, $C$7:$C$27 ) ),$C:$C, 0 ) ) :
  INDEX($E:$E, MATCH( MIN( IF( $C$7:$C$27 > $H7, $C$7:$C$27 ) ),$C:$C, 0 ) - 1 ),
- INDEX($D:$D, MATCH( MIN( IF( $C$7:$C$27 >= $G7, $C$7:$C$27 ) ),$C:$C, 0 ) ) :
  INDEX($D:$D, MATCH( MIN( IF( $C$7:$C$27 > $H7, $C$7:$C$27 ) ),$C:$C, 0 ) - 1 ) ) )  

1. 表1显示的时间为Double

一个。总计为Double：在S7 中输入此ArrayFormula，然后向下复制（单元格编号格式为0.?? "Hrs."）

= IF( $Q7 > $R7, "!Err", SUM(
  INDEX($O:$O, MATCH( MIN( IF( $M$7:$M$27 >= $Q7, $M$7:$M$27 ) ),$M:$M, 0 ) ) :
  INDEX($O:$O, MATCH( MIN( IF( $M$7:$M$27 > $R7, $M$7:$M$27 ) ),$M:$M, 0 ) - 1 ),
- INDEX($N:$N, MATCH( MIN( IF( $M$7:$M$27 >= $Q7, $M$7:$M$27 ) ),$M:$M, 0 ) ) :
  INDEX($N:$N, MATCH( MIN( IF( $M$7:$M$27 > $R7, $M$7:$M$27 ) ),$M:$M, 0 ) - 1 ) ) )  

b.总计为TimeSerial：在T7 中输入此ArrayFormula，然后向下复制（单元格编号格式为[hh]:mm）

= IF( $Q7 > $R7, "!Err", 1/24 * SUM(
  INDEX($O:$O, MATCH( MIN( IF( $M$7:$M$27 >= $Q7, $M$7:$M$27 ) ),$M:$M, 0 ) ) :
  INDEX($O:$O, MATCH( MIN( IF( $M$7:$M$27 > $R7, $M$7:$M$27 ) ),$M:$M, 0 ) - 1 ),
- INDEX($N:$N, MATCH( MIN( IF( $M$7:$M$27 >= $Q7, $M$7:$M$27 ) ),$M:$M, 0 ) ) :
  INDEX($N:$N, MATCH( MIN( IF( $M$7:$M$27 > $R7, $M$7:$M$27 ) ),$M:$M, 0 ) - 1 ) ) )  

Answer 2

嗯，一个解决方案是 ARRAY FORMULA CTRL+SHIFT+ENTER

    =SUMPRODUCT(INDIRECT("C"&MATCH(MIN(IF($A$1:$A$12>E4,$A$1:$A$12)),A:A,0)-1&":C"&MATCH(MIN(IF($A$1:$A$12>=D4,$A$1:$A$12)),A:A,0))-INDIRECT("B"&MATCH(MIN(IF($A$1:$A$12>E4,$A$1:$A$12)),A:A,0)-1&":B"&MATCH(MIN(IF($A$1:$A$12>=D4,$A$1:$A$12)),A:A,0)))

但它使用INDIRECT，这在大型数据库上可能会很慢。绿色单元格包含公式。

我之前添加了一个日期。您还可以输入表格中没有出现的日期。

我跳过了am 和pm，但如果单元格被正确格式化为日期应该没有问题。