Excel VBA：`range.find()` 找不到显示为 `####` 的值

Question

我正在尝试在特定列中查找特定值。例如B 列中的值100000。以下代码仅在列宽到足以显示完整数字时才有效：

Dim rngSearchRange As Range
Set rngSearchRange = ThisWorkbook.Worksheets(1).Columns(2)
Dim searchTerm As Variant
searchTerm = 100000

Dim rngResultRange As Range       
Set rngResultRange = rngSearchRange.Find(What:=searchTerm, lookin:=xlValues, lookat:=xlWhole)

一旦列变窄，因此 Excel 仅在特定单元格中显示 ##### 而不是 100000，查找方法返回 Nothing。

有没有办法根据实际值而不是值的显示来使用查找方法？如果没有，是否有任何替代 For Each cell In rng.Cells 的方法？最终，我正在寻找使用最少资源的方法。

注意：searchRange 只有一列，searchValue 要么不存在，要么只存在一次。

注意：使用 match() 时有一个 followup question 注意：尽管数据和代码都没有改变，但它似乎有时会起作用。不幸的是，我无法重现更改。这整个事情可能确实是一个错误

Answer 1

如果列宽太窄，可以重现 Find 失败。

Match 没有这个问题。

Sub dural()
    Dim rngSearchRange As Range
    Set rngSearchRange = ThisWorkbook.Worksheets(1).Columns(2)
    Dim searchTerm As Variant
    searchTerm = 100000
    Dim rngResultRange As Range

    Dim found As Variant
    found = Application.Match(searchTerm, rngSearchRange, 0)

    If Not IsError(found) Then
        Set rngResultRange = rngSearchRange.Cells(found)
        MsgBox rngResultRange.Address
    End If
End Sub

根据您的用例，这可能是一个选项，或者如果不是，也许Range.AutoFit？虽然“我正在尝试在特定列中查找特定值”，但听起来这可能是一个选项。

Answer 2

您可以将范围放入一个数组并循环该数组，或者只使用 MATCH：

    Sub test()
        Dim rngSearchRange, rngResultRange As Range
        Dim searchTerm As Variant
        Dim vRow As Variant

        Set rngSearchRange = ThisWorkbook.Worksheets(1).Columns(2)
        searchTerm = 10000
        vRow = Application.Match(searchTerm, rngSearchRange, 0)
        If Not IsError(vRow) Then
            Set rngResultRange = rngSearchRange.Resize(1, 1).Offset(vRow - 1, 0)
        Else
            MsgBox "Not Found"
        End If
End Sub

Answer 3

试试这个：

Sub test()
   Dim rngSearchRange, rngResultRange As Range
   Dim searchTerm As Variant

   Set rngSearchRange = ThisWorkbook.Worksheets(1).Columns(2)
   searchTerm = 10000
   Set rngResultRange = rngSearchRange.Find(what:=searchTerm, LookIn:=xlValues)
End Sub

Answer 4

find 的问题在于它仅出于某种原因查找显示的值，这与您按 crtl+F 或单击“主页”功能区上的“查找并选择”选项时的搜索框行为相同。目前没有已知的方法来解决这个问题（查看 xlValues 等 cmets 指出的） 由于有多种方法可以解决这个问题，（最慢）但最可靠的方法是使用 foreach 循环：

For Each cel In rngSearchRange
If cel.Value = searchTerm Then
Set rngResultRange = cel
exit for '<-If you want the first result, leave this. If you want the last result, omit. Using the first result could be significantly quicker as it will stop looping right away.
End If
Next cel

只需确保将范围设置为确定值，例如 Range("A1:B87") 而不是 Columns(2)，因为这会引发类型不匹配错误。如果要搜索 B 列，请改用Range("B:B")。

Answer 5

这是一个作弊版本：它将范围复制到临时工作表，将公式转换为值，并在那里进行查找。

Public Function FindValueInRange(ByVal RangeToSearch As Range, ByVal ValueToFind As Variant) As Range
    Dim WasActive As Worksheet, ScreenUpdating As Boolean, Calculation As XlCalculation
    'Store current position
    Set WasActive = ActiveSheet
    ScreenUpdating = Application.ScreenUpdating
    Application.ScreenUpdating = False
    Calculation = Application.Calculation
    Application.Calculation = xlCalculationManual

    'Let's get to work!
    Set FindValueInRange = Nothing 'Default to Nothing
    On Error GoTo FunctionError

    Dim TempSheet As Worksheet, FoundCell As Range, DisplayAlerts As Boolean

    'Create Temp Sheet
    Set TempSheet = Worksheets.Add

    'Copy data to Temp Sheet, in the same location
    TempSheet.Range(RangeToSearch.Address(True, True, xlA1, False)).Value = RangeToSearch.Value

    'Column Width to Maximum!
    TempSheet.Range(RangeToSearch.Address(True, True, xlA1, False)).EntireColumn.ColumnWidth = 255

    'Search the cells in the Temp Sheet
    Set FoundCell = TempSheet.Range(RangeToSearch.Address(True, True, xlA1, False)).Find(ValueToFind, LookIn:=xlFormulas, LookAt:=xlWhole)

    'Return the found cell, but on the original Worksheet
    If Not (FoundCell Is Nothing) Then Set FindValueInRange = RangeToSearch.Worksheet.Range(FoundCell.Address(True, True, xlA1, False))

    'Remove the Temp Sheet
    DisplayAlerts = Application.DisplayAlerts
    Application.DisplayAlerts = False
    TempSheet.Delete
    Application.DisplayAlerts = DisplayAlerts
    Set TempSheet = Nothing

FunctionError:
    On Error GoTo -1 'Reset the error buffer
    'Restore previous position
    WasActive.Activate
    Application.Calculation = Calculation
    Application.ScreenUpdating = ScreenUpdating
End Function

然后会像这样使用：

Set rngResultRange = FindValueInRange(rngSearchRange, searchTerm)