数组中的通配符搜索

Question

我有一个数组，其中包含一堆常用术语，用于表示该字段正在等待采购订单。然后我有一个循环向后遍历一大列数据，删除单元格中的值与数组中的任何项都不匹配的任何行。为此，我使用一个函数（我在网上找到）来测试该值是否存在于数组中。

到目前为止一切顺利，只要单元格中的值与数组中的值完全匹配。出错的地方是如果单元格包含对常用术语之一的轻微变化（即“TBC - 稍后会跟进”，甚至只是“TBC”而不是“TBC”）

我需要一种方法来获取单元格中的值并对数组中的值进行通配符搜索。我不会粘贴我所有的代码（现在这是一个开发中期的混乱），但如果我们可以在下面实现它，我可以应用它。

Sub TestFilterArray()
MyArray = Array("tbc", "awaiting po", "po to follow")
If IsInArray("tbc xyz", MyArray) = False Then
    MsgBox "No! Item is not in the array"
Else
    MsgBox "Yes! Item is in the array"
End If
End Sub

Function IsInArray(stringToBeFound As String, arr As Variant) As Boolean
  IsInArray = UBound(Filter(arr, stringToBeFound)) > -1
End Function

这当前返回“否！...”，因为“tbc xyz”不在数组中，但如果有意义的话，我希望它返回“是！...”，因为“tbc *”在那里。

感谢任何帮助。

Answer 1

Function IsInArray2(StringToBeFound As String, MyArray As Variant) As Boolean
IsInArray2 = False
For i = LBound(MyArray) To UBound(MyArray)
    If "*" & MyArray(i) & "*" Like StringToBeFound Then IsInArray2 = True 'will match MyArray to any substring of StringToBeFound
Next
End Function

考虑到运行时考虑，它变成了

Function IsInArray2(StringToBeFound As String, MyArray As Variant) As Boolean
IsInArray2 = False
For i = LBound(MyArray) To UBound(MyArray)
    If "*" & MyArray(i) & "*" Like StringToBeFound Then
        IsInArray2 = True 'will match MyArray to any substring of StringToBeFound
        Exit Function
    End If
Next
End Function

谢谢你的评论。回首往事，是的，Like 声明反其道而行之，抱歉。让我用一个案例和冗余匹配器和一个测试来弥补它的重要性。

Function IsInArray2(stringToBeFound As String, MyArray As Variant) As Boolean
IsInArray2 = False
For i = LBound(MyArray) To UBound(MyArray)
    If LCase(stringToBeFound) Like LCase("*" & Replace(MyArray(i), " ", "*") & "*") Then
        IsInArray2 = True 'will match MyArray to any substring of StringToBeFound
        Exit Function
    End If
Next
End Function

Sub TestFilterArray()
MyArray = Array("coca cola gmbh", "awaiting po", "po to follow")
If IsInArray2("Coca Cola Deutschland GmbH", MyArray) = False Then
    MsgBox "No! Item is not in the array"
Else
    MsgBox "Yes! Item is in the array"
End If
End Sub

Answer 2

此代码似乎可以满足您的要求：

Option Explicit

Sub TestFilterArray()
Dim MyArray As Variant
MyArray = Array("tbc", "awaiting po", "po to follow")
If arrMatch("tbc xyz", MyArray) = False Then
    MsgBox "No! Item is not in the array"
Else
    MsgBox "Yes! Item is in the array"
End If
End Sub

    Function arrMatch(stringToSearch As String, Arr As Variant) As Boolean
    Dim sS As String, sF As String
    Dim I As Long

sS = " " & Trim(stringToSearch) & " "
For I = LBound(Arr) To UBound(Arr)
    sF = "*" & Trim(Arr(I)) & "*"
    If sS Like sF Then
        arrMatch = True
        Exit Function
    End If
Next I

arrMatch = False
End Function